*save_checkpoint

*text_image chap_9.png center Chapter Nine
*temp aphrodite 1
*temp wanttobefriend false
*temp allformortals false
*temp keptquiet false
*temp aggro false
*temp reason false
*temp foreplay 1
*temp ridehim false
*temp skippedforeplay false
*temp interruptedforeplay false
*temp hedoesit false

If you thought delivering nightmares was demanding, it was only because you had never planned a feast that could lead to a war, alongside a goddess that might wage one over tablescapes.

Industrious, Zeus had called Aphrodite. A gross understatement. Obsessive, or perhaps tyrannical, would've been better.

Commending her commitment to–and eye for–curating the right aesthetic might be easier if you weren't the one running around the realms, laying the groundwork for it to materialize.

Still, laying said groundwork is about more than meeting Aphrodite's lofty hosting standards. Your position in the pantheon, not to mention the future of the realms, could very well be determined by your performance. @{(hermesoutcome < 3) Especially after your disastrous confrontation with Hermes. The herald will be on guard, and, though you haven't seen him around since, it wouldn't surprise you if he had already plotted your demise. Or, at the very least, your sabotage|Especially now that your business with the Messengers' Council is on hold}.

Which is why you apply yourself to the tasks she sets you….

*choice
    #Vigorously. I push myself as hard as I must to get the job done.
        Exhaustion is near impossible to come by as an deity. Your immortal bodies are made to withstand pretty much anything. 

        Argus may have tested @{(injured) your|Morpheus's} immortal body's limits, but he hadn't breached them. The fact @{(injured) you were|he was} standing so promptly after the Giant's attack is @{(morpheusoutcome > 4) proof, as is everything the pair of you did in the aftermath|proof}.

        *if fitness > 60
            *set befriendrival %+10
            *set pantheonplayer %+20
            *set aphrodite 1
            Aphrodite's demands are exhaustive, yes, but they don't exhaust you.

            How could they? You've been traveling between realms ever since you took on your duties all those mortal lifetimes @{(hobby) ago|ago, and have cultivated even further physical prowess with equally as many lifetimes' worth at the gymnasium|ago|ago}. You're in peak shape, and excel at every challenge Aphrodite throws your way.
            *goto impressedaphrodite
        *else
            *set befriendrival %-10
            *set pantheonplayer %-15
            *set aphrodite 2
            That's why it's so surprising, when you realize Aphrodite might succeed where Argus failed.

            @{(hobby) She's|Not even your several lifetimes' worth of training at the gymnasium spare you. She's|She's|She's} utterly, implacably relentless. 
            
            Under her barrage of orders, you're on a constant rotation between Olympus, the Underworld and Leukas, barely managing to stop for enough nectar and ambrosia to keep you going.

            And it wears you out. It wears you out bad.
            *goto pissedaphrodite
    #Graciously. I want us to get along, and not just because it's what's best for the realms.
        *set wanttobefriend true
        She may be extremely demanding, but she's also extremely knowledgeable.
        
        Ultimately, she's a goddess with a vision. You can't fault her for doing everything in her power to bring that vision to life. 

        In fact, her determination and creativity impress you. The pair of you may have gotten off to a rocky start, but that doesn't mean you can't admire her grit.

        And it shouldn't mean you can't be friends, either.
        *if charm > 60
            *set befriendrival %+25
            *set pantheonplayer %+10
            *set aphrodite 1
            Fortunately, she seems to think so too.
            *goto main66
        *else
            *set befriendrival %-15
            *set pantheonplayer %-10
            *set aphrodite 2
            Emphasis on [i]shouldn't[/i]. 

            Despite your best efforts to be cordial–charming, even–the goddess of love seems intent on hating you.
            *goto main66
    *if (didnotwarntheron = false) and (theronreason != 3)
        #Half-heartedly. I'm more invested in helping secure Leukas, duty be damned.
            *set allformortals true
            Their survival is paramount.

            Who cares about floral arrangements and silverware placement when an entire people's fate hangs in the balance?

            Certainly not you.

            *if dutiful < 35
                *set befriendrival %-5
                *set peoplepleaser %+20
                *set worship %+10
                *set aphrodite 3
                If it means defying Zeus, and antagonizing Aphrodite, so be it.

                All that matters is the Leukans. 

                You work alongside them, rising their concerns with the committee, even if it leads to endless in-fighting. 

                This is their island. Their home. Not a board of petteia for Zeus to play his games upon.
                *goto pissedaphrodite
            *else
                *set befriendrival %-15
                *set peoplepleaser %-10
                *set pantheonplayer %-10
                *set aphrodite 4
                Unfortunately, dividing your attention between the two means you excel at neither. 
                *goto pissedaphrodite
    #With great aplomb. It'll show the pantheon I can handle this and more.
        You'll never rise through its ranks if you can't deal with a single goddess. 

        Even if said goddess is a handful and then some.

        Alas,
        *if leadership > 65
            *set befriendrival %+10
            *set respect %+15
            *set aphrodite 1
            despite her efforts to get under your skin, you excel, comporting yourself with the poise and resilience expected of your station with ease.
            *goto impressedaphrodite
        *else
            *set befriendrival %-10
            *set respect %-15
            *set pantheonplayer %-10
            *set aphrodite 2
            despite your best efforts to remain steadfast, and to comport yourself with the poise and resilience expected of your station, you can't help but struggle.

            And your work suffers for it.
            *goto pissedaphrodite

*label impressedaphrodite

The goddess of love is impressed with you as a result, even if she tries to hide it.
*goto main66

*label pissedaphrodite

Aphrodite is very unimpressed as a result, as is the rest of the pantheon.

*label main66

That much becomes clear during the committee's latest gathering.

*page_break 

You have taken to meeting in Leukas's temple, though Aphrodite refuses to call it that. Instead, she refers to it as "the hovel."

It's certainly more rustic than other mortal cities' worship centers. Theron had told you he hadn't got round to replacing its previous keeper-the man who had given him his scar-and it shows. A slanted roof supported by two rows of six columns, built and rebuilt with wood, not stone, and overgrown with woodland. 

Were it not for its striking location, Aphrodite might have a point. But the front of the temple crests the edge of a cliff overlooking Leukas's rolling coastline, and the back is surrounded by a cedar forest that makes the air always smell fresh and green.

Besides, just because it's a rather simple, often times deserted structure, doesn't mean the Leukans don't worship well or grandly. They just do so the old way. With makeshift shrines, little offerings and spontaneous prayers to deities where their influence is strongest.

*page_break

Theron is already there when you arrive, accompanied by his general and his @{(allformortals) mother. You|mother, who} had insisted they be included in the decision-making process. It had required some convincing, however. 

Athena, in particular, had been vehemently opposed to the idea. According to the goddess, hosting such a feast was an honor that should've been bestowed upon a hero, not, in her own words, some ill-bred carpenter with delusions of grandeur.

In the end and despite her tantrums, Zeus had allowed them to attend.

Following that fraught encounter with him and Hera in their throne room, the thunder god had descended on Leukas to deliver the news with the rest of you in tow. 

*if (didnotwarntheron = false) and (zeustheron > 4)
    Theron had taken your advice from the night before to heart. 
    
    @{(zeustheron) Already, there had been ships moored and waiting on the island's East coast, and he had begun diverting some of the supplies Zeus had granted the island to them as soon as they'd been carted in|Already, there had been archers practicing on targets strung up high, and weavers stitching cloths with foliage for camouflage|A feast had been arranged to mark Zeus's arrival. And though only a few oxen had been sacrificed in the god's honor, and the pitchers passed around contained more water than wine, the music, dancing and laughter had warmed Zeus to the island's bucolic charm|na|}.
    *goto athenaarrival
*else
    Zeus had been rather taken with Leukas's bucolic charm, much to Athena's chagrin. Theron had certainly spruced the place up, and poured plenty of effort into keeping the Olympian on side.

    Effort that is evidently paying off.
    *goto athenaarrival

*label athenaarrival
*page_break

"Goddess," he greets you, inclining his head, his laurel circlet glinting in the sunlight.

His companions follow 
*if didnotwarntheron
    suit. His general, a young, cheerful woman named Roxana, with far more reverence than his mother.

    Kleia, her name is. She has been watching these meetings with a bright-eyed curiosity that belies her age. An advanced age, for a mortal. The deep lines carved into her face and the stark white of her hair are confirmation.

    Still, her many years in Hellas are nothing but a blip in time for a deity, and certainly don't exempt her from showing you due respect.  
    *goto athenaarrival1
*elseif aphrodite = 4
    suit, though you can't help but notice his general, a usually cheerful woman named Roxana, does so with perhaps less reverence than is wise, for a mortal in the presence of a deity.

    You can't really blame her. It was she who paid the price when you'd forgotten to deliver one of her messages to Aphrodite. In your defense, you had been juggling too many errands at once, including securing double the crops for Leukas in the coming spring.

    Still, the poor general had gotten an epic dressing-down as a result.
    *goto athenaarrival1
*else
    suit, his mother with @{(awkwardkleia) an aloof smile|knowing grin}, and his general, a cheerful woman named Roxana, with a @{(allformortals) warm|reverent} one.
    *if allformortals
        The pair of you have been working together on ensuring the feast has as minimal an impact on the Leukans as possible, and it was thanks to her clever maneuvering that you managed to secure double the crops for the island in the coming spring.
        *goto athenaarrival1
    *else
        *goto athenaarrival1

*label athenaarrival1

@{(aphrodite) "How nice of you to arrive promptly,"|"How nice of you to arrive promptly for a change,"|"Scheming already, I see,"|"How nice of you to arrive promptly for a change,"} Aphrodite quips, startling the mortals when she steps out from behind one of the columns.

Theron, who had thrusts an arm in front of his mother, retrieves it to bow in her direction. One again, Roxana, who had reached for her bow, and Kleia, who had rolled her eyes, follow suit.

Aphrodite merely laughs, but the sound is drowned out by the hoot of an owl reverberating across the sky.

You spot it in the distance, a gliding speck of gold against a swathe of bright blue, followed by two deities you recognize immediately.

"Here she comes," Aphrodite grumbles.

*fake_choice
    #"Brace yourselves," I warn.
        @{(aphrodite) Aphrodite smirks|Aphrodite smirks despite herself|Aphrodite smirks|Aphrodite smirks despite herself}.
    #"Behave yourselves," I urge.
        "Never," Aphrodite vows, @{(wanttobefriend) making you smile|making you roll your eyes}.
    #"Save yourselves," I joke.
        @{(aphrodite) Aphrodite smirks|Aphrodite smirks despite herself|Aphrodite smirks|Aphrodite smirks despite herself}.

"We ought to get Hephaestus to fix this place up before the feast," Athena sighs as soon as she lands, Zagreus at her heels. 

She's a stately goddess, tall even by deity standards, dark-haired and broad-shouldered, with long, wide wings that match her owl's and clad in gleaming armour that threatens to eclipse the sun.

Upon hearing her husband's name, Aphrodite stiffens, which is precisely why Athena mentioned him. If there's one thing you've learned about the goddess of wisdom and war in your recent dealings, it's that she wields the former to wage the latter with barbed precision. 

How have you been coping with such unnecessary snidery?

*choice
    #By making myself a target in order to spare the others.
        You can't bear to see them wilt under Athena's cruel and clever attacks.

        "Nonsense, this is an easy fix," you say, rapping on one of the columns and managing not to flinch when a fresh crack forms as a result. "Hephaestus has bigger things to worry about." Literally. The god is working hard building all sorts of contraptions to aid the pantheon against the Giants. "Surely we're resourceful enough to handle this ourselves?"

        *if ruthless < 40
            *set pantheonplayer %+10
            *set befriendrival %+5
            *set Zagreus %+5
            It works. 

            Athena's glare crashes into you, grinding and unforgiving.

            "You? Resourceful?" Athena's laugh is mirthless. "You are aware I read your reports, yes?"
            *goto main67
        *else
            *set pantheonplayer %-15
            *set Zagreus %-5
            Athena grins, and you realize too late she's onto you. 

            "Resourceful?" She pins her gaze on Zagreus, whose nonchalant shrug doesn't fool you. "I hope your understanding of resourcefulness is better than your brother's, otherwise we should save ourselves the hassle and burn this wretched insult to temples to the ground right here, right now."
            *goto main67
    #By keeping my distance so that she doesn't target me.
        *set keptquiet true
        She's far too cruel and clever to attempt anything else.

        *if demure > 60
            *set befriendrival %-5
            *set maverickgoddess %+10
            Especially since this–being all reserved and mild-mannered around her–has been working so well for you.
            *goto main67
        *else
            *set maverickgoddess %-15
            But reservedness isn't enough to spare you this time.

            "Have something to say, Nightmares?" Athena asks, pinning her gaze on you. "Perhaps you'd like to volunteer your skills for the task instead? A demotion from errand girl to laborer can be easily arranged." 
            *goto main67
    #By matching her energy and targeting her hard in return.
        "Aren't you also the goddess of crafts?" you challenge, lifting your chin. "Surely this falls under your jurisdiction. Though I suppose you have a point. Hephaestus does have a superior eye for design."

        It pays to remind Olympians they don't have a monopoly over back-handedness.

        *if charm < 40
            *set underworldinfluence %+10
            *set befriendrival %+10
            *set Zagreus %+5
            Especially when you brandish it so skillfully yourself. Athena's eyes widen, and she seems torn between shock and annoyance.

            Even after clearing her throat, all she manages is a meek "Exactly."
            *goto main67
        *else
            *set olympusinfluence %-15
            Athena's eyebrows soar. "Settle down, errand girl. Leave the jurisdiction to the deities that matter."

            Shame bites your cheeks, and you feel @{(theronoutcome > 2) Theron and Zagreus|Zagreus} tense.
            *goto main67

*label main67
*page_break

"Can we please just focus on what we came here to discuss?" Aphrodite gestures at the beach stretching beneath the temple, where the feast will be held.

It took much deliberation to reach that decision, and an endless back and forth between the pantheon and the Leukans. But back and forth you'd gone, @{(aphrodite) working tirelessly to bring Aphrodite's vision to life|and round and round in circles too|working tirelessly to ensure the feast didn't take place in the agora. The furthest from Leukans' homes this charade could unfold, the better|and round and round in circles too}.

"Fine," Athena allows, flicking her aegis and causing everyone to flinch.

The cloak may be finely woven, with a snakeskin trim and enough fabric to be draped this way or that depending on Athena's needs, but that doesn't fool you. It's sturdy as a shield, and just as mighty. Especially since twisting it a certain way reveals the gorgon head hiding within the threads.

The gorgon head with eyes that could turn you all to stone with a single glance.

Athena wouldn't dare–or at least you don't think she would–but you can tell she enjoys the way it keeps everyone around her on edge.

"Your seating plan will not work," she adds, fingering the aegis's trim.

And so the bickering, bargaining and beseeching begins.

It makes even the dicier Messengers' Council meetings seem like a breeze.

*page_break

Athena insists that Hephaestus ought to build a huge throne for Zeus to sit on alone, so Olympus can project power and might.

Aphrodite thinks that will irritate the Giants–and, more importantly, ruin the laid-back luxury aesthetic she's going for–while Zagreus is adamant that the Underworld ought to be held in equal standing. The goddess's solution is a platform with a long table for key deities to sit at, while your brother thinks four thrones would be better.

Theron, on the other hand, is worried building anything at all is pointless, as the Giants could smash it and wield the debris to cause further destruction.

Who do you side with?

*fake_choice
    #Athena. Zeus is Olympus's chief Giant-slayer and has earned the right to sit center stage.
        *set feastdecor 1
        *set dutiful %+5
    #Athena. If the Giants attack, let them go for Zeus and his ridiculous throne first.
        *set feastdecor 2
        *set cunning %+5
    #Aphrodite. A platform with a long table atop it is more likely to keep the peace.
        *set feastdecor 3
        *set diplomacy %+5
    #Zagreus. The Underworld fought in the Gigantomachy too, and is a realm in its own right.
        *set feastdecor 4
        *set Zagreus %+5
    #Theron. Having witnessed the Giants' capacity for destruction, I'd rather not make it easy.
        *set feastdecor 5
        *set underworldinfluence %+5

"@{(feastdecor) Athena|Athena|Aphrodite|Zagreus|Theron} is right," you determine.

*if allformortals
    @{(feastdecor < 5) You're committed to ensuring mortals' safety, yes, but that doesn't mean you have to agree about how that safety manifests|You're not just siding with him because you're committed to ensuring mortals' safety. This is the best option. For them, and for everyone}.

    *if (aphrodite = 4)
        @{(feastdecor < 5) Roxana manages to disguise her huff of indignation with a cough|"Of course you would think so," Aphrodite huffs}.

        @{(feastdecor < 5) Though he hides it better, Theron is miffed too|Theron casts a grateful glance your way. Even Roxana seems pleased. Or, at least, less ready to burn any offerings made in your name}.
        *goto main68
    *else
        *if feastdecor = 5
            Theron and Roxana both cast grateful glances your way.
            *goto main68 
        *else  
            Agreement is certainly the last thing you feel from the three pairs of mortal eyes than land on you after you speak. Kleia is studying you with a thoughtful expression, Roxana with a deep frown. 

            But it's Theron's gaze you mee. Trust me, you mouth at the Lord. You've proven yourself so far, haven't you?

            He nods, unclenching his fists.
            *goto main68
*elseif wanttobefriend
    *if feastdecor = 3
        It isn't just about helping the goddess realize her vision, either. Not only will this aggravate the Giants less, it will also keep the bickering within the pantheon to a minimum.
        *goto main68
    *else
        Yes, you admire the goddess and want to help her realize her vision. But that doesn't mean you'll do what she wants blindly, especially if you don't agree with it.
        *goto main68
*else
    *goto main68

*label main68

@{(feastdecor) "I knew you had a sliver of sense in there somewhere," Athena notes, though she sounds more pleased with herself than you|"I knew you had a sliver of sense in there somewhere," Athena notes, though she sounds more pleased with herself than you|"Of course I'm right. Well done for noticing," Aphrodite chirps|Zagreus casts you a grateful glance. "Thank you."|"Thank you, Goddess," Theron says. Courteous, yes, but also genuine}. 

"It is settled, then," you confirm before the arguing can resume. 

It shouldn't, not now that a majority as been reached. But you never know, with this bunch.

Athena's owl, who had been perching on a nearby branch overseeing the proceedings with far more interest than a bird ought to show on proceedings of any kind, lets out a high-pitched squawk. 

Whatever information it contains causes Athena to fasten her gaze on the coast. Her eyes are grey, but not the gloomy shade of Zeus's; gleaming silver, and sharp as steel. It softens when they settle on the ship sailing towards the shore, however.

A ship you know all too well. 

*page_break Medea's

Or, you suppose, Jason's, the priestess's rather drab paramour.

"This is not the ship they set sail on, the ship [i]I[/i] designed," Athena points out, examining the galley with grim eagerness.

"Ah, yes, the ship had been badly damaged when it first docked here, Goddess," Theron offers promptly. "I took the liberty of making some…modifications alongside carrying out repairs." 

He was smart enough not to say improvements.

"Fine work, too," Zagreus compliments him. "She's fast."

He's too busy marveling at the ship to notice Athena's expression sour further.

"I suppose we ought to gather the last of our winter supplies. If they didn't eat us out of house and home last time, they certainly will now," Kleia says, and Athena's eyes skewer her instead.

To her credit, Theron's mother holds the rage in them without @{(aresoutcome > 2) flinching, and your thoughts flicker to Ares. How many times has he been on the receiving end of his sister's wrath? How many times has he wilted under her wrath? Felt the sting of her mockery? Likely nn eternity's worth|flinching}.

"The only thing you ought to do, mortal, is hold your tongue," the goddess snaps. "Hosting this feast is an honor this blot of an island has done nothing to deserve. An honor that should be its own reward. And yet, you are being handsomely compensated for it, are you not?"

@{(aphrodite) They are.|They are.|They are, thanks to you.|They are, but it's no thanks to you.} This spring will be extra generous to the island, and the ensuing harvest extra bountiful.

Provided it isn't destroyed, that is.

*fake_choice
    *if (didnotwarntheron = false) or (theronreason != 3)
        #"Back off," I warn Athena.
            It's your turn to bear the brunt of her glare. Her eyes glow with rage, and you're certain she might've summoned her famed spear, maybe even hurled it at you, if her owl hadn't squawked anew.

            The ship is almost at the shore.
    *if (didnotwarntheron = true) or (theronreason = 3)
        #"Back off," I warn Kleia.
            Theron presses his lips into a tight line, presumably to keep that steely composure of his from fleeing him. If anything ought to chase it away, it would be disrespecting his mother.

            Alas, Athena has a point. And, if the Leukans get too greedy, she'll be well within her right to punish them for it.

            Wether because she realizes her mistake, or how it might come back to haunt her son, Kleia averts her gaze and utters, "Of course, Goddess. My apologies."
    #"Why are they back so soon?" I deflect.
        Athena shifts her focus from Kleia to you. "Why not? They are heroes. This island may be dull and uninspiring, but it is also the best place in all of Hellas for them to make their glory."

        Roxana clenches her fists, but Theron lightly shakes his head, warning her off protesting.
    #"Are we done here?" I sigh.
        "We better be," Aphrodite chimes in, popping the bubble of tension that had become of the temple.

        Kleia averts her gaze, and Athena returns hers to the ship.
        
"There are some nymphs I must @{(aphrodite > 1) scream at|praise}," Aphrodite announces, twisting a lock of rose-gold hair between her fingers.

You @{(aphrodite > 1) smother a wince. The nymphs in question had been tasked with creating garlands, but you had made a mistake when you had delivered Aphrodite's message, and they had woven them out of laurel instead of olive|bite back a smile. The nymphs in question had been tasked with weaving garlands, and would've done so out of laurel leaves as usual. But you'd heard Aphrodite mention she wanted olive leaves instead, and were able to intervene to make it so}.

"Well?" Athena asks, silver gaze fixing on Theron. "Shouldn't you greet them? This is [i]your[/i] island, after all. Or do you not observe my father's sacred hospitality tenets?"

"Of course we do," Roxana pipes up. She's almost as tall as the goddess, and wider-set.

It wouldn't make a difference. Should she charge her, the mortal wouldn't stand a chance.

Fortunately for Roxana, Athena seems far more interested in the heroes. She launches herself off the cliff and her owl follows. The pair glide towards the vessel, matching wings beating the breeze in unison.

"Come, let us give our guests a proper Leukan welcome," Theron says, practically dragging his general away. 

"Yes, Lord." She spits out the last word, and you remember what Theron had told you in the agora the night you @{(dancedwiththeron) danced|watched him dance}. [i]Nobody calls me Lord. Other than my general, but she does so exclusively to mock me[/i].

Kleia excuses herself, then promptly follows after her.

*if theronoutcome > 2
    Before he joins them, Theron's gaze finds yours, and you share a fleeting look before he takes up the rear, and the three mortals disappear into the woods.
    *goto main69
*else
    Theron takes up the rear, and the three of them disappear into the woods.
    *goto main69

*label main69
*page_break

Despite having nymphs to @{(aphrodite > 1) discipline|commend}, Aphrodite remains in the dilapidated temple, watching Athena wait for the heroes to finish pushing Theron's ship onto the sand.

"Look at how smoothly she glides over those waves," Zagreus gushes, still taken by the ship's design.

"Look at how much she hates it," Aphrodite beams, gaze fixed on Athena's arrow-straight back.

Zagreus leans in closer in that flirty, conspiratorial way of his. "Forget thrones or platforms. Let us all greet the Giants in Jason's masterfully repaired ship."

You don't know what surprises you more, Zagreus openly mocking an Olympian in front of another Olympian, or Aphrodite laughing heartily about it.

In truth, neither should. Anything that disparages Athena delights Aphrodite. And working alongisde Athena has been @{(aphrodite > 1) as hard for Zagreus as working alongisde Aphrodite has been for you|far more taxing for Zagreus than working alongside Aphrodite has been for you}.

Which reminds you….

*page_break Get Back To Work

The thinner the moon grows, the closer the feast–and your mother's ultimatum–looms.

It has shrunk to a sliver
*if hermesoutcome < 3
    *set punishmentdecide 3
    *set irisdecides true
    *set eleos true
    when she seeks you out on one of your many errands. The fact she's come to Leukas when she's meant to be coordinating the Underworld's attack strategy is alarming enough. Meeting her gaze only spooks you further.

    "${(name)}. Come," the Queen of the Underworld urges. "Zeus has called us to Theron's house."

    You frown. @{(theronoutcome > 2) "Is Theron alright?"|"Why?"}

    @{(theronoutcome > 2) "He's already there."|"C'mon."} She loops her arm through your elbow and drags you into the air, almost making you drop a jug of nectar. "Iris has found proof of Hermes's misdeeds."
    *goto prehermesscene
*elseif (hermespunishment = 4) or (hermespunishment = 5)
    *set eleos true
    by the time @{(punishmentdecide) the Leukans decide|Morpheus decides|na} on a punishment for Hermes.
    *goto prehermesscene
*else
    when you cross paths with Iris on the beach. The last time you encountered them was
    *if (hermesoutcome > 5)
        when they witnessed Hermes's oath. Before he was confined. Before they were made interim Leader of the Messengers' Council. The Messengers' Council has had few dealings since.
        *goto iriscatchup
    *else
        *set hermesleader true
        when they witnessed Hermes's oath. The Messengers' Council has had few dealings since.
        *goto iriscatchup

*label prehermesscene
*page_break

A small contingent of deities has gathered @{(punishmentdecide) in Theron's courtyard|in Zeus's throne room|in Theron's courtyard} for the occasion. @{(punishmentdecide) The agora was far too public, and|Small, because|You assume it's small and not in the agora because} Zeus wants to keep this from becoming a spectacle.

"We do not want the Giants to know we are in-fighting and presume us weak," the thunder god @{(punishmentdecide < 3) had explained last time you'd crossed paths on one of Aphrodite's errands|is telling Hera, who is listening with vague interest}. "But we also do not want them to think we will not punish one of our own when they step out of line."

Morpheus and Iris are already here. The Messengers' Council, come together once more, to witness its Leader be torn apart.
*if punishmentdecide = 3
    The aide's eyes an impenetrable black. When they meet yours, the shade shifts to soft brown, and you glimpse the turmoil beneath their calm and collected surface.

    @{(morpheusoutcome > 2) Morpheus casts you a concerned glance|Morpheus tosses you one of his self-satisfied smirks}. Theron and Roxana are here too, the only mortals in attendance. If the Lord is overwhelmed by the presence of so many deities in his home at once, he's doing a good job at hiding it.

    Rounding out the company, sagging against one of the grand marble column with her head firmly bent towards the grand marble floor, is a goddess you never expected to see in the flesh.
    *goto eleosintro
*else
    Hera and your mother are here, @{(punishmentdecide) too, and Theron and Roxana, the only mortals in attendance|too|na}.

    Them, you had expected. Unlike the goddess sagging against a column in the corner.

    You've never met her before, but you know her, or rather, know of her.
    *goto eleosintro

*label eleosintro
*page_break

Eleos, goddess of mercy, pity and compassion.

And a devoted recluse who seldom leaves her cave in the outskirts of Athens.

Her face is mostly hidden beneath a thick, long veil that flutters every time she sniffles.
        
And she sniffles quite often.

*if irisdecides
    "You made it. Good," Hera greets you, swiftly extricating herself from Zeus's elucidating. 
    *goto hermesscene1
*else
    It is the only sound breaking the thick, expectant silence pressing down on the 
    *if punishmentdecide = 1
        @{(didnotwarntheron) courtyard|courtyard. A vastly different atmosphere from the last time you were here. No fire around which to gather and tell stories, no pallets upon which to lie and marvel at the stars}. The only source of light is the glow emanating from the sheer amount of deities congregated here.
        *goto hermesscene1
    *else
        throne room.
        *goto hermesscene1

*label hermesscene1
*page_break

"Morpheus," @{(irisdecides) the goddess adds|Hera says, making everyone stiffen}. "Will your father be joining us?"

A muscle works in his jaw. He hides it behind a cold smile. "Alas, he will not. I believe he overexerted himself last night, and would rather we dealt with this unfortunate matter while he recovers."

Hera and Zeus share a look of relief.

*if irisdecides 
    "Well then." Hera continues, turning her attention to you and waving her hand. A collection of scrolls appears before you. "Whave an update on Argus's escape. Iris here was able to find proof that Hermes was targeting Leukas to steal worship. Apparently, these do not match the instructions you've been receiving. Instructions my husband approved."
    
    One after the other, you skim the hastily jotted down words on each scroll.

    There's no mention of Leukas, or the other patronless cities Hermes has been asking you to target. 
    
    "That is correct," you tell Hera.

    She nods, as though she expected as much, then bids the scrolls disappear. Beside her, Zeus grows somber.

    "When Iris brought us these, alongside copies of the ones they had been delivering, I did not want to believe them," he laments. 

    Your gaze darts between Morpheus and Iris. The aide must've known Morpheus was copying the scrolls. Keeping his own record of Hermes's messages, in case the herald was altering the official one. And he was right. You bet he would love to hear you say that aloud.

    *fake_choice
        #I definitely will, sometime.
            *set Morpheus %+10 
            Credit where credit's due.
        #Maybe I will, sometime.
            *set Morpheus %+5
        #Unfortunately for him, I never will.
            *set Morpheus %-5

    You realize, then. @{(spiedonhermes) This is what you would've found in the Archives. What Iris found instead|This also explains why Hermes didn't want Iris near the Archives. Not that it stopped them, in the end}. If only you @{(spiedonhermes) hadn't got caught red-handed|had managed to reel him in}, it would be you standing next to Zeus, about to deliver Hermes's punishment.
    
    "You neglected to tell us Morpheus had been targeted during Argus's attack, Persephone," Zeus says, pinning your mother with an accusatory glance. "If you had, we might have tracked down anyone who meant the dream god harm and discovered Hermes's plot sooner."

    Your mother lowers her chin. Guilt twists through you like a knife. "An oversight on my part," she says.

    Before Zeus can berate her further, Morpheus intervenes. "The Queen can't be blamed for not bringing this to your attention earlier. I happened to be close to Tartarus when Argus escaped, so my injury could've easily been the result of mere misfortune." He smiles roguishly. "Besides, tracking down everyone who means me harm would take an eternity. I have no shortage of enemies, you see."
    *goto harpiesarrive
*else
    *goto harpiesarrive

*label harpiesarrive

@{(irisdecides) Before he can say anything else,|Then} three lightning bolts cleave the sky, and a cacophony of eagle-like cries follows in their wake.

Harpies.

*label hermesscene2
*page_break

@{(punishmentdecide) They slam into the courtyard, whipping up a gust of wind that almost sends Eleos's veil flying into the night|They burst into the throne room, eagle-like wings whipping up a gust of wind that almost sends Eleos's veil flying|They slam into the courtyard, whipping up a gust of wind that almost sends Eleos's veil flying into the night}.

@{(irisdecides) Two of them, with sharp faces and even sharper talons that screech against the floor when they drag Hermes before the Olympian rulers|Her sniffling only grows more frequent once she wraps it around herself anew. The harpies pay her no mind, however}. One keeps her sharp claws firmly fastened on Hermes's shoulders, while the other curtsies before Zeus.

He looks more dishevelled than a deity ought to look, though it could just be the absence of his satchel and staff. His wiry frame twitches under his father's glare, but the harpies keep a clawed hand on each of his shoulders, tethering him to the ground.

"@{(punishmentdecide) Deities. Mortal|Deities|Deities. Mortal}," Zeus @{(irisdecides) booms, sounding a lot more official than he had moments ago|booms}. "We have gathered here to bear witness to Hermes's punishment."

*if irisdecides
    Hermes tenses under the harpies' grasp. 

    "What have you to say for yourself, herald?" Zeus asks the God.
    *gosub_scene subroutines hermeszeus
    Still sagging against her column, Eleos begins softly weeping.
    *goto hermesscene3
*else
    While Zeus lists Hermes's transgressions, whose reaction do you study?

    *fake_choice
        #Morpheus's.
            *set Morpheus %+5
            He has his arms crossed and his smirk in place. But both his stance and his expression have a brittleness to them, as though they might break with the slightest shift.
        *if punishmentdecide = 1
            #Theron's.
                set Theron %+5
                He has schooled his face into a wall that reveals nothing of what he might be feeling behind it. Unlike Roxana, whose gaze keeps flitting between the attendees with a mixture of curiosity and apprehension.
        #Iris's.
            *set respect %+10
            They wear a blank expression, their eyes an impenetrable black. Have you ever seen them this somber? This devoid of color?

            It's a rather unsettling sight.
        #My mother's.
            *set parents %+5
            She egaerly taps her sandal on the floor. Like everyone else, she's swamped, and wants this done, and done quick at that.
        #Eleos's.
            *set cunning %+5
            Her affinity for others' emotions keeps her from seeking out company or spreading her cult, lest she become burdened by their feelings. Their suffering.

            So who summoned her here?

    *goto hermesscene3
    
*label hermesscene3

"Tell us, @{(punishmentdecide) Theron, Lord of Leukas. What punishment have your people|Morpheus. What punishment have you|aide. What punishment have you} decided upon?" Zeus asks.

@{(punishmentdecide) Theron steps into the center of the courtyard, regarding Hermes with cool calm.|Morpheus glides into the center of the throne room, regarding Hermes with a modest–for Morpheus–amount of smugness. Probably because he wants to appear dignified, not because he isn't enjoying this.|Iris regards Hermes with a coolness you know they dont' feel, no matter how gloomy they make their eyes. "It will not be I who delivers his punishment, but those he hurt most."}

*if punishmentdecide != 2
    @{(irisdecides) The aide nods at Theron, who steps into the center of the courtyard. When|When} he speaks, he does so 

    "You deprived my people of peaceful sleep for months, made us sick with worry and drove us to near madness with exhaustion.The heart of a deity is an unfathomable thing, for a mortal, so I will not pretend to know yours. But @{(irisdecides) with wondrous Iris's blessing, my|my} people and I have decided that you should know ours."
    *goto decidedpunishment1
*else
    "Physical pain is such an alien feeling, for beings such as ourselves. On the few occasions we experience it, it's fleeting. Easily dismissed," he says. 
    
    Then he spreads his wings, showcasing his @{(injured) scar. It is far larger than yours, and more gnarled. More obvious. If he hadn't snatched you out of the way in time, would yours be the same? You don't get the chance to dwell on it|long, gnarled scar}. Iris gasps, their eyes flickering from impenetrable black to bright amber. Eleos's weeping grows louder.

    Which, you suppose, is precisely why he did it.

    "Not this." He flicks the scarred wing. "No, this pain laid roots in my bones, and the memory seared into my mind is as hideous as the scar seared into my wing. So, I thought I would practice generosity for once, and share some of it with you."
    *goto decidedpunishment1

*label decidedpunishment1
*page_break

@{(irisdecides) Still weeping|Softly weeping under her veil}, Eleos approaches the herald.

@{(punishmentdecide) Revenge empathy. Only Morpheus could've pulled off such a punishment|Empathy. Of course that's the punishment Theron has chosen|Empathy. Of course that's the punishment Theron has chosen. And of course Iris decided to grant him it. They will be handsomely rewarded in worship for it too, even if that isn't why they did it}. 

What would you have done?

*fake_choice
    #Gone softer on him.
        *set ruthless %-5
        To feel the pain he's caused, all at once, in front of an audience no less, is too much.
    #Gone harder on him.
        *set ruthless %+5
        *set harsher true
        @{(punishmentdecide) He's|He's|They're} letting Hermes off the hook easy. A literal slap on the wrist would've been more suitable.
    #The same.
        *set diplomacy %+5
        An eye for an eye, and all that.

@{(harsher) Though, judging by the way Hermes reacts when Eleos approaches him, he doesn't agree. He|At Eleos's approach, Hermes} drops the @{(irisdecides) brash|bored} act.

The harpies have to hold him down so the goddess can press a pale hand to his heart. The other, she presses over @{(punishmentdecide) Theron's|Morpheus's|Theron's}. Finally, she lifts her head high enough for you to get a good look at her face. Round, or perhaps puffy, with downturned lips and big, blue eyes filled with tears.

When she closes them, they streak down her finely-freckled cheeks, a journey so well-trodden it has left perpetual marks. And she gets to work. @{(punishmentdecide) Theron's|Morpheus's|Theron's} chest begins to glow. Pale blue light that roams up Eleos's arm, across her own chest, then all the way to Hermes's.

Nothing happens, at first. The glow sinks into Hermes and he merely twitches.

But, the more light flows from @{(punishmentdecide) mortal to god|god to god|mortal to god}, the more his demeanor shifts. Soon, the harpies have to hold him up, rather than down, as he thrashes against their talons like a fish on a hook.

@{(punishmentdecide) Or a mortal plagued by horrible nightmares, tossing and turning in their sleep|Or a god being chased by a Giant while a mountain crumbles around them|Or a mortal plagued by horrible nightmares, tossing and turning in their sleep}.

Then the @{(punishmentdecide) weeping|screaming|weeping} starts.

*page_break

@{(punishmentdecide) "Please," he begs. "Please make it stop."|His contorting becomes more violent, and he hunches over himself, bracing against a foe only he can see|"Please," he begs. "Please make it stop."}

The wings at his helm and sandals strain to meet the air, flapping frantically around him. @{(punishmentdecide) Exhaustion claims his face. Under the blue light, it no longer looks youthful and divine,|Fear and blue light cut into his face, no longer youthful and divine,|Exhaustion claims his face. Under the blue light, it no longer looks youthful and divine,} but haggard in a way you've never seen a god's face look.

@{(punishmentdecide) Because you've never seen a god carry the pain, fear and fatigue of hundreds of mortals at once. And|And|Because you've never seen a god carry the pain, fear and fatigue of hundreds of mortals at once. And} neither have the others, judging by their reactions. No matter how stoic Hera and your mother appear, how glumly Zeus looks on, how desperately Iris tries to cling to aloofness, they're all rattled by it. You can feel it.

*if punishmentdecide = 2
    Morpheus, too. Even if he hasn't moved, hasn't so much as blinked since Eleos put her hand to his chest. There's no trace of his usual smirk, no mischief or lightness in his violet eyes. 

    Only grim determination.
    *goto itsover
*else
    The only ones who aren't hiding their unease are Roxana and Morpheus. The general is clearly worried about Theron, who hasn't moved other than to close his eyes against the brightness. It isn't worry what tugs at Morpheus's brow.

    It's sorrow, the same kind that overtakes him whenever he speaks of Pasithea.
    *goto itsover

*label itsover
*page_break Then It's Over

Eleos removes her hands with a wistful sigh, and the light that had emanated from her body goes out, like an exhale. Hermes sinks into the Harpies anew. @{(punishmentdecide) Theron bows his head at Eleos before returning to Roxana's side|Morpheus regards him coldly. "Don't worry, it shall pass soon enough."|Theron bows his head at Eleos before returning to Roxana's side}.

*if irisdecides
    "Harpies. Take my son to his chambers, where he shall remain confined until such a time I deem appropriate," Zeus tells them before turning to Iris. "I am appointing you interim Leader of the Messengers Council in the meantime."

    The aide nods. 
    *goto itsover1
*else
    "Harpies. Return my son to his chambers," he orders.
    *goto itsover1

*label itsover1

The harpies obey, swiftly dragging Hermes @{(punishmentdecide) into the sky anew|away once more|into the sky anew}.

"We are done here," Zeus announces. "Leave @{(punishmentdecide) us|us. I have important matters to discuss with our gracious host|us}."

@{(punishmentdecide) Theron|Morpheus|Theron} looks a little shaken. Not like Hermes was–he's still steady on his feet, for one. But not half as @{(punishmentdecide) composed|unfazed|composed} as usual. You can't blame him. Not after what you just witnessed.

*if (punishmentdecide != 2) and (theronoutcome != 2)
    "Good luck," you mouth at him before you make for the exit.
    
    He sneaks you a smile in return. And though it's faint, it chases away some of the shadows clinging to his face.
    *goto posteleos
*else
    Save for @{(punishmentdecide > 1) Hera,|the Lord, Hera, and Roxana,} the rest of you take your leave. 
    *goto posteleos

*label posteleos

Eleos flees as soon as you @{(punishmentdecide) leave Theron's home behind|exit the throne room|leave Theron's home behind}, faster than even the harpies had been, as though she can't wait to return to her solitude.

"Princess," Morpheus @{(punishmentdecide) says, bowing to you before he bows to your mother|says, his voice surprisingly steady as he bows to you, then to your mother|says, bowing to you before he bows to your mother}. "Queen Persephone."

She smiles at him politely. @{(irisdecides) "Nice deflection back there, Morpheus."|"Morpheus."}

He hesitates, eyes darting between the pair of you. @{(morpheusoutcome > 2) If your mother weren't here, would he launch into one of his usual quips? Somehow, judging by the softness in his gaze when it brushes yours, you don't think so. Alas, you don't get the chance to find out, for|No doubt if the Queen wasn't here, he would launch into one of his usual quips. Alas, he thinks better oof it and} promptly takes to the sky, leaving a trail of shadow through Iris's rainbow.

"I must update your father." Your mother gently cups your @{(parentsrel) cheek|cheek, ignoring your reflexive eye roll|cheek}. "Behave."

*page_break Resume Your Duties

At least that's your intention when you return to the @{(punishmentdecide) beach|Leukan beach|beach}.

"${name}! Hold up!" Iris call after you, landing on the sand in a flurry of white feathers and colorful light.

The Messenger' Council has had few dealings since @{(irisdecides) you were appointed to the committee|everything went down with Hermes}.

*label iriscatchup

@{(hermesleader) Whether because Hermes is avoiding you, or because he's just as swamped as everyone else, you can't say. With|With} nightmares temporarily suspended and you receiving orders directly from Zeus, you doubt there would be much for you to do were a meeting be arranged.

You've seen @{(hermesleader) your fellow messengers around|seen them around} @{(eleos) though. Even before this harrowing business with Eleos|though}. Just because mortals are, for now, not being met with terror in their sleep doesn't mean they're not meeting the ends the Fates devised for them. 

*if eleos
    @{(irisdecides) And now, it will be Iris alone guiding their souls to the Underworld. They dead will undoubtedly be|But it's been Iris alone guiding their souls to the Underworld. And though the dead undoubtedly} better off for it, @{(irisdecides) but it won't be|it isn't exactly} light work.

    "That was…a lot," they say.
    *if irisdecides
        "Necessary. But a lot."

        *fake_choice
            #"You did well, putting a stop to it," I praise them.
                "I hope the Fates agree," they sigh.
            *if harsher = false
                #"Perhaps it was too much," I reprimand them.
                    "Maybe," they sigh.
            *if harsher
                #"It could've been a lot worse," I dismiss them.
                    "Maybe," they sigh.
            #"Did you want something?" I ask them.
                What's done is done. They succeeded where you failed.

                Why linger on it more than you must?

                They rise an eyebrow at you, taken aback. 
        *goto irisinvite
    *else
        *goto irischat
*else
    @{(hermesleader) And guiding their souls to the Underworld|But now, it's Iris alone guiding their souls to the Underworld. And though the dead are undoubtedly better off for it, it} isn't exactly light work. And it never stops. Not for politics, not for Giants, not for the prospect of war.

    A prospect which has also kept Morpheus occupied. Dreaming, or rather, the hope it can bring, is more important than ever for the Leukans. 
    
    @{(morpheusoutcome > 3) And, it would seem, for Morpheus. You can feel the hope in every stolen glance, every tentative wave, every soft smirk whenever you spot him out on a delivery|And whenever you spot Morpheus out delivering it, he keeps a respectful distance}.

    "Busy?" Iris asks.
 
    *fake_choice
        #"Always."
        #"Unfortunately."
        #"Could be worse."

    That draws a smile out of them, but it's short-lived.
    
    *if hermesleader
        "I can believe it," they say. Then their eyes turn a foggy shade of grey. "Much has happened since we last spoke."

        Though they can't talk about the oath they witnessed–nor outwardly judge you for it–you can tell they want to.
        *goto irisinvite
    *else
        *goto irischat

*label irischat

@{(eleos) "Thank you for putting a stop to it."|"I wanted to thank you for uncovering Hermes's deceit. For putting an end to it, too."}

Then they worry their lip, eyes flickering between soft amber and deep blue before they add, "I should've known. @{(hermeslying) I knew he was lying, I just thought|I thought} he was merely overwhelmed. I never expected…but I should've. I should've."

*fake_choice
    #"You're not to blame," I reassure them.
        They smile gratefully, even if doubt lingers in their gaze.
    #"Let this be a lesson, then," I scold them.
        "You're right," they say. "I ought to be more vigilant, from now on."
    #"We're not out of the woods yet," I warn them.
        They nod in agreement.

*label irisinvite

Then they glance at the torch-lit beach, where preparations for the feast continue, even at this hour. The majority of the Leukans have retired for the night, but most immortals remain. Long-haired nymphs, one-eyed cyclops, shore-hugging tritons. Some tend to their duties–weaving and carpentering and garland-making–but most are reveling. Not a feast, exactly, but not far off either.

"I have a message for you," Iris says. You expect them to pull a scroll from their satchel, but instead they point to the edge of the cliff where the temple perches. "Aphrodite wishes to see you at once."

You frown. @{(aphrodite > 1) She seldom summons you|You frown. You've gotten so good at anticipating the goddess's demands, you're seldom summoned} like this; out of the blue and in a hurry.

"I had better do as she asks, then."

*page_break Make For The Temple

Nothing could've prepared you for the scene that greets you when you descend: Aphrodite, kneeling by a column, filling the cracks in the wood with wax.

An array of tools is scattered at her feet and, though it's dark, your goddess eyes can tell they've already been put to good use. The loose tiles on the roof have been fixed, and the floor cleared of debris. The weeds pushing through them remain, however.

"What are you doing?" you ask, too bewildered to remember yourself.

She pauses her task long enough to @{(aphrodite > 1) shoot you a withering glare|rise a perfect eyebrow at you}. "What does it look like I'm doing? Seriously, harpymeat. @{(aphrodite > 1) Could you be any less perceptive?|You may be a good little messenger, but your perception skills are apalling}."

@{(wanttobefriend) Fair. Sort of|Uncalled for}.

"Much as it pains me to say it, Athena was right. This hovel needed fixing up and I would rather cut off my own tongue than tell her that or ask my [i]husband[/i] to do it. Everyone else is busy, so here I am, donning rags and getting my hands dirty."

You wouldn't call the silk chitoniskos she's wearing rags. Her hands aren't that dirty either. 

"Which brings me to you, harpymeat." She aims her scraper at you. "Please tell me you inherited some of your mother's knack for coaxing nature to do her bidding? These weeds are rather stubborn."

"Alas, I did not."

She wrinkles her perfect nose.

@{(aphrodite > 1) "Of course. I should've guessed you would be useless at this, too."|"Shame."}

*if (aphrodite = 1) and (wanttobefriend = true)
    *set friendly true
    *fake_choice
        #"Do you want my help or not?" I ask, suppressing an eye roll.
            "Of course I want you to help," she snaps.
        #"Shame indeed," I agree, making a big show of studying my nails.
            She rolls her eyes. 

            "You're really going to make me say it? Fine. Help me. Please." 
        #"I take it you want me to leave, then?" I ask, @{(flightstyle) flexing my wings|bidding my shadows lift me|flexing my sandals' wings}.
            "No!" she blurts out. Then she clears her throat, as though realizing how desperate she sounded. "I mean, would you stay? Please."

    You smile triumphantly. "That's what I thought."
    *goto helpaphrodite
*else
    *choice 
        *if wanttobefriend = false
            #Demand she back off or else. I won't be spoken to like this any longer.
                *set aggro true
                You draw yourself to your full height and aim your gaze at her like you might your weapon.

                "Hate me all you want. I couldn't care less. But, unless you wish to discover exactly how nightmarish I can be, do not speak to me like that ever again. Am I making myself clear?"

                Her fingers tighten around the scraper, as though she might hit you with it.

                *if charm < 30
                    *set befriendrival %-20
                    But she doesn't. Instead, she lets out a long, almost tired sigh.
                    *goto aphroditechat
                *else
                    *set maverickgoddess %+15
                    *set befriendrival %-10
                    *set foughtaphrodite true
                    *goto aphroditechat
        #Attempt to dialogue with her. Why does she insist on treating me with such disdain?
            "Look, I know we got off to a rough start. But must you be so incessantly cruel? Can't we attempt to find a way to work together with, if not mutual respect, a modicum of politeness at least?"

            *if diplomacy > 60
                *set befriendrival %+10
                *set reason true
                You know your way around conflict. How to sound both corteous and convincing. How to appear firm but friendly.

                It's a tried and tested approach, one that works wonders on Aphrodite, much to your surprise.

                "You're right," she says.
                *goto aphroditechat
            *else
                *set befriendrival %-10
                *set olympusinfluence %-5
                *set foughtaphrodite true
                Your aim was to be courteous, maybe even convincing. 

                Instead, you sound whiny, as though a petulant child, and not a goddess, spoke the words.
                *goto aphroditechat
        #Help her out. Just because she can be unkind doesn't mean I have to be as well.
            *if ruthless < 40
                *set befriendrival %+15
                *set friendly true
                *goto helpaphrodite
            *else
                *set befriendrival %-10
                *goto hinderedaphrodite
        #Help her out. I'd rather flex my muscles than pore over scrolls any day.
            *set fit true
            *if fitness > 60
                *set befriendrival %+5
                *set olympusinfluence %+10
                *set friendly true
                *goto helpaphrodite
            *else
                *set befriendrival %-5
                *set olympusinfluence %-10   
                *goto hinderedaphrodite     

*label helpaphrodite

@{(reason) Then you turn your attention to the tools, eager to extend a token of good will|You examine the tools}.

"I may not be a nature goddess," you tell her. "But I know my way around a hoe."

Her lips quirk up. "Suit yourself."

You plug away in surprisingly comfortable silence. You, hacking at the weeds, her, fixing up the wood.

They're stubborn alright, @{(fit) but you make quick work of removing them all the same. It feels good to do something physical, to put your strength to the test and win, to see your hard labor pay off even before you finish it. Unlike so much of what you've been doing lately, this is tangible, and your success easily measured|and you quickly understand why Aphrodite was hoping for some of your mother's power to help remove them. Still, it doesn't deter you}.

*if reason = true
    *goto main70
*else
    *goto aphroditechat

*label aphroditechat
*page_break 

"I suppose @{(friendly) you|you would} think me callous, @{(friendly) don't|wouldn't} you?" Aphrodite @{(friendly) sighs into the silence, startling you|concedes}. "You who was born of love, and who has always known its warmth. Whose parents won't force her to marry against her will, no matter how hard Zeus campaigns for it. Whose worship doesn't hinge on how beautiful, how desired, she is perceived to be."

@{(aggro) It's a good thing you're not the one holding the scraper, otherwise you might hurl it at her. How dare she presume anything about your life? Your parents? Your cult?|You freeze. How could she possibly know any of that?}

"Oh, please," she says, as though she can read your mind. @{(friendly) But there's no malice in her tone.|She's never looked–or sounded–this unimpressed with you before}. "I am the goddess of love, harpymeat. I can sense how much of it your family @{(parentsrel) shares|shares, even when you seem intent on pretending otherwise|shares, even when you yourself foolishly doubt its presence}. I am also the goddess of desire. I can see all they desire is for you to be happy."

The words are laced with @{(friendly) sorrow|bitterness}, which only grows when she adds, "I don't have a mother. And my father, well, I'm sure you've heard the poems."

Of course you've heard the poems. Aphrodite's father was the primordial sky god–and vicious tyrant–Uranus. So powerful, his ichor alone was enough to sire a daughter when it was spilled.

What remains of him is buried in the deepest, darkest depths of Tartarus.

*page_break Thank The Fates

"Well, they are nothing but drivel," Aphrodite adds @{(friendly) softly|sharply}. "I didn't just emerge from the waves my father's blood fell upon fully fledged. I was a godling. Young and unwary and alone. It didn't matter. Not to the Fates, not to the gods, and not to mortals. I know that, because I could [i]feel[/i] it the same way you can feel a fear lurking in the Halfrealm. And what they wanted from me was far from my comfort, or my safety, or my happiness."

@{(friendly) A remote expression overtakes her moonlit face|Her expression hardens, moonlit face stony and cold as a statue's}.

"It's why I'm so good at this." She gestures at the beach stretching beyond the cliff's edge. "It isn't just about garlands and tablecloths. It's about Zeus's desire for obedience and admiration, the Giants' desire to be heard, mortals' desire to survive. Nobody can play to those desires like I can."

She pauses, holding you gaze with
*if friendly
    an earnestness you didn't know she was capable of. "But I do appreciate your efforts to aide me in doing so. @{(aphrodite) You are a rather capable goddess, harpymeat|Even if they don't always pan out|Even if the Leukans are clearly your priority|Even if they don't always pan out."}

    You smile at her, grateful for both the honestly and the compliment. "Thank you." 
    *goto main70
*else
    an intensity that @{(charm < 30) would've made anyone else recoil|almost makes you recoil}.
    *goto tenseaphrodite

*label hinderedaphrodite

@{(foughtaphrodite) Her grin sharpens. "Well, then. Glad that's settled. Now make yourself useful and get to weeding."|Sighing you plug away at the weeding.}

@{(foughtaphrodite) Sighing, you do as she orders, muttering under your breath. You| You} may not be a nature goddess, but you know how to use a hoe.

Or so you thought.

The weeds are stubborn alright.
*if fit
    Removing them tests your strength as much as it does your patience.

    "All that grunting is very unseemly. You sound like one of Circe's pigs," Aphrodite observes.

    You ignore her, yanking at the weeds, and almost throwing your back out in the process.

    Aphrodite merely chuckles.

    "Can you not?" you snap. Whether out of pain or embarrassment, you can't be sure.
    *goto aphroditechat
*elseif foughtaphrodite = true
    Removing them tests your strength as much as it does your patience.
    *goto main70
*else
    Worse than their reluctance to be removed is Aphrodite's insistence on testing your resolve to be the bigger goddess, not to mention the kinder one.

    "You call that helping?" she scoffs, eyeing your handiwork with nothing but disdain.

    "It's more than you deserve," you snap, immediately forgetting yourself.
    *goto aphroditechat

*label tenseaphrodite
*page_break

"So please don't mistake my callousness for ignorance. If I don't behave in the way you want me to, it isn't because I don't know it's what you want. Believe me, I do. It's because I don't care," Aphrodite concludes.

*if aggro = true
    @{(foughtaphrodite) "Well, that makes two of us," you seethe. But you sound more petulant than frightening|Her puffed-up chest and mean eyes are convincing, you'll give her that. But all you have to do is step forward and the bravado abandons her}.

    *if foughtaphrodite
        *goto hinderedaphrodite
    *else
        *set leftaphrodite true
        Fear takes its place.            
        *goto tenseaphrodite1
*elseif reason = true 
    *goto tenseaphrodite1
*else
    "Well, that makes two of us," you huff.

    *if foughtaphrodite = true
        *goto main70
    *else
        Then you return your attention to the weeds.
        *goto main70

*label tenseaphrodite1

"Though I suppose I could stand to be more polite about it," she @{(aggro) adds quickly, as though afraid of what you might do if she doesn't|sighs}.

"Good," you @{(aggro) grunt|agree, smiling tentatively}.
*if reason = true
    *goto helpaphrodite
*else
    "I look forward to it."

    With that settled, you leave her to it.
    *goto main70

*label main70
*page_break

But, @{(leftaphrodite) as you return to the beach,|the harder you throw yourself at sprucing the place up, the harder} her words haunt you.

@{(friendly) Not the honesty, nor the compliment|Not the self-aggrandizing nonsense}. No, the stuff about your family. About your happiness.

It crystallizes your feelings about your mother's ultimatum.

About your future, and what you desire for it.

*fake_choice
    #Happiness.
        *set desire 1
    #Peace.
        *set desire 2
    #Empowerment.
        *set desire 3
    #Family.
        *set desire 4

You know where to find it. Or rather, who to find it with.

*if (((theronoutcome > 2) and (aresoutcome > 2)) and (morpheusoutcome > 2))
    *set others true
    Though it hasn't always been the case, though at times it has felt like your heart was being pulled in different directions, torn between the two gods and the mortal oh so effectively vying for its affections, there's no doubt about it now.

    @{(marriage) If you put aside what's best for the realms, there's|If you put aside your ambition, there's|There's|There's} one name and one name alone seared into it.

    *choice
        #Ares.
            *set chose 1
            *goto areschoice
        #Theron.
            *set chose 2
            *goto theronchoice
        #Morpheus.
            *set chose 3
            *goto morpheuschoice
*elseif (((theronoutcome > 2) and (aresoutcome > 2)) and (morpheusoutcome < 3))
    *set others true
    Though it hasn't always been the case, though at times it has felt like your heart was being pulled in different directions, torn between the god and the mortal oh so effectively vying for its affections, there's no doubt about it now.

    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into it.

    *choice
        #Ares.
            *set chose 1
            *goto areschoice
        #Theron.
            *set chose 2
            *goto theronchoice
*elseif (((theronoutcome < 3) and (aresoutcome > 2)) and (morpheusoutcome > 2))
    *set others true
    Though it hasn't always been the case, though at times it has felt like your heart was being pulled in different directions, torn between the two gods oh so effectively vying for its affections, there's no doubt about it now.

    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into it.

    *choice
        #Ares.
            *set chose 1
            *goto areschoice
        #Morpheus.
            *set chose 3
            *goto morpheuschoice
*elseif (((theronoutcome > 2) and (aresoutcome < 3)) and (morpheusoutcome > 2))
    *set others true
    Though it hasn't always been the case, though at times it has felt like your heart was being pulled in different directions, torn between the god and the mortal oh so effectively vying for its affections, there's no doubt about it now.

    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into it.

    *choice
        #Theron.
            *set chose 2
            *goto theronchoice
        #Morpheus.
            *set chose 3
            *goto morpheuschoice
*elseif (((theronoutcome < 3) and (aresoutcome < 3)) and (morpheusoutcome > 2))
    *set chose 3
    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into your heart.

    Morpheus.
    *goto morpheuschoice
*elseif (((theronoutcome < 3) and (aresoutcome > 2)) and (morpheusoutcome < 3))
    *set chose 1
    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into your heart.

    Ares.
    *goto areschoice
*elseif (((theronoutcome > 2) and (aresoutcome < 3)) and (morpheusoutcome < 3))
    *set chose 2
    @{(marriage) If you put aside what's best for the realms, there's|If you put aside ambition, there's|There's|There's} one name and one name alone seared into your heart.

    Theron.
    *goto theronchoice
*else
    *set chose 4
    @{(desire < 4) Yourself and yourself alone|In the Underworld, where it has always been. With your parents, your brother, Averna. With Cerberus and your Epiali and every soul lighting the hazy sky}.
    *goto nonechoice

*label areschoice
*page_break

How could it not be? 

*if aresoutcome = 3
    Whatever doubts you might have had dissipate as soon as you picture his smile, the kindness with which he treats everyone around him, the openness he has always afforded you, both in person and in his scrolls.
    *goto areschoice1
*else
    Warmth blooms in your chest whenever you think of his easy smile, the kindness with which he treats everyone around him, the openness he has always afforded you, both in person and in his scrolls.
    *goto areschoice1

*label areschoice1

Still, part of you can't help but wonder; would he choose you, if you weren't what was best for the realms?

*goto main71

*label theronchoice
*page_break

@{(theronoutcome < 4) Depriving yourself of his company hasn't lessened how much you crave it. How much you crave him|You can't deny it}. But admitting so fills you with despair, for a future with him is out of reach.

And even if you did dare reach for it, if you were foolish enough, selfish enough, to do such a thing, what kind of future would it be?

One where he doesn't get to grow old with someone the way his parents have, the way he's always dreamed of doing.

One where his nights are either lonely or full of terrors.

One where he dies and you're left to grieve him, forever.

That's not a future.

*page_break That's A Tragedy

[i]What of Pasithea?[/i] 

The whisper steals into the back of your mind, hope that cuts.

Because wasn't what happened to Morpheus's mother a tragedy too? 
    
Didn't it shatter her life, her world, her son?
*goto main71

*label morpheuschoice
*page_break

Fates, how it pains you to admit it.

But it's the truth.

@{(unsureaboutmorpheus) There's something between you, something you can't deny|Has been, perhaps from that very first Messengers' Council meeting, all those mortal life spans ago}.

A truth that has only grown stronger with every taunt, every quarrel, every flower on the gate @{(unsureaboutmorpheus) since that very first Messengers' Council meeting all those mortal life spans ago|since}.

But does he feel the same way? @{(morpheusoutcome) na|na|All he has given you are brooding looks and loaded silences|Or was kissing you a heat of the moment thing?|Or was what happened between you a heat of the moment thing?|Or was what happened between you a heat of the moment thing?}

@{(morpheusoutcome > 3) Not exactly a romantic declaration. Then, an even worse thought infiltrates your mind|Or worse}. Was it just another game? Another elaborate way to torment you?
*goto main71

*label nonechoice
*page_break

To marry would be the opposite of that. Would be to betray yourself.

@{(marriage) You thought you would do it for the good of the realms, but you can't. You won't|Advancing your position in the pantheon isn't worth that. Nothing is|And that, you will never do.|And that, you will never do}.
*goto main71

*label main71
*page_break

*if leftaphrodite = true
    *if chose = 4
        The realization fills you with relief. It carries you through your duties, and then all the way back to the Underworld.

        To your family.
        *goto main72
    *else
        *goto declaration
*else
    @{(chose) "Of course he would,"|"Does it matter?"|"It wasn't,"|"I'm glad you realized it,"}, Aphrodite offers, @{(friendly) startling you anew|startling you}.

    "Excuse me?"

    She lets out an exasperated sigh.

    @{(chose) "You're panicking about whether Ares wants you, or whether he wants what's best for the realms."|"You're panicking about your future with that mortal."|"You're panicking about whether the god of dreams is toying with you."|"I'm glad you realized you have all the love you need."} She pauses, shooting you a knowing look before adding,
    *if chose = 4
        *if (reason = true) or (friendly = true)
            *set templerestored true
            "And I'm glad you won't be strong-armed into sacrificing that."

            @{(reason) You nod gratefully.|"I'm sorry you were," you say softly.}

            @{(reason) You could get used to this polite version of the goddess.|She waves you off. "Nothing to be done about it now."}

            You work through the night, parting ways only when dawn peeks over the horizon, and the temple has been fully restored.
            *goto main72
        *else
            "Now quit ruminating and get to work."

            You do, filled with relief at finally accepting your fate. Relief that carries you through the night, acting like a shield against Aphrodite's jabs, and then all the way back to the Underworld. 

            To your family.
            *goto main72
    *else
        *set aphroditehelped true
        "Don't."

        *fake_choice
            #"Why shouldn't I?" I lament.
                "Quit moping," Aphrodite scolds you.
            #"It's not that simple," I argue.
                "Sure it is," Aphrodite counters.
            #"Must you read my mind?" I grumble.
                "Yes, I must," Aphrodite snaps.
            #I say nothing, too consumed by my thoughts.

        You pull at a weed grabbing onto the base of a column in hopes it will distract you.

        "Were you not listening when I explained I can sense love? Feel others' desires? Embody them, if I so wish?" Aphrodite huffs. @{(chose) "Ares has always thought of you fondly, even before that feast. And after it, well, that fondness only grew. We don't talk much these days."|"I've seen the way the pair of you make eyes at each other in meetings, and across the agora, and on the beach|I've seen the way the pair of you make eyes at each other across the sky|na}.

        *if chose = 1
            She pauses gripping the scraper tighter.

            "And yet, I always knew when he was expecting a scroll from you, could feel his nerves and anticipation through Olympus's thick, marble walls. I always knew when it had arrived, too, because joy radiated off him like heat from the sun."
            *goto aresbit
        *else
            She pauses to smirk, then adds, @{(chose < 3) "It doesn't matter, that he's mortal. It doesn't matter that your future could be full of pain. Nothing shakes the webs woven by the Fates like love does. Nothing determines their patterns so resolutely either.|Nothing shakes the webs woven by the Fates like love does. Nothing determines their patterns so resolutely either. And while they like to toy with us about it, I can tell that what's between you is more than just a game}."
            *goto aresbit

*label aresbit

@{(chose > 1) Her amusement vanishes. She|She} fixes her gaze on the sea, but not before you catch the regret lurking in their depths.

Ares told you he and Aphrodite never truly loved one other. But perhaps he was @{(chose > 1) mistaken. Perhaps that's who she's thinking about as she stares at the shore, all wistful melancholy|mistaken}.

"For Fates' sake, harpymeat. I didn't love him," she snarls. "Not in the way that matters, the way that makes the Fates' pay closer attention to the their work."

"But ain Olympus, you warned me off him. Threatened me about it, actually," you remind her.

"Of course I did. I may not have loved Ares, but his affections were certainly good for worship."

You had suspected as much.
*if (friendly = true) or (reason = true)
    *set templerestored true
    The pair of you have come a long way since. As evidenced by Aphrodite gently saying, "So quit your ruminating, and trust me when I tell you there's no need for it."

    You do, at least until the temple is promptly and fully restored and the pair of you part ways.

    "What a nice little heart-to-heart we had." She pats invisible dirt off her alleged rags. "Let's do it again some time, yes?"

    When she disappears into the night, she leaves you with her cloying scent and the overwhelming need to find @{(chose) Ares|Theron|Morpheus|na}.
    *achieve aphroditefavor
    *goto declaration1
*else
    Still, her honestly surprises you. And makes you suspicious.
    *goto toldoff

*label toldoff
*page_break

"Why are you telling me this?" you ask, wondering if perhaps you did get through to her, after all. Maybe even @{(aggro) browbeat her into being nice|impressed her}.

Alas, her answer proves otherwise. "Because I want you to quit your rather distracting–and frankly, pathetic–ruminating, and get to work."

She leads by example, returning her focus to patching up the columns, and berating you for every little mistake and wayward thought thereafter.

When you finally part ways, the temple looks less dishevelled–though not entirely restored, much to Aphrodite's annoyance. 

Not that it bothers you. There's only one thing you care about as you take to the sky. One place you wish to be. One desire you wish to satisfy.
*goto declaration1

*label declaration

By the time you realize what you're doing–[i]where[/i] you're going–you're @{(chose) through the Cloud gate and at Zeus's doorstep|almost at Theron's balcony|at the Horn Gate|na}.

Your @{(flightstyle) wings|shadows|sandals} have acted of their own accord, seemingly emboldened by all Aphrodite's talk about wants and desires.
*goto declaration2

*label declaration1
*page_break 

The flight @{(chose) to the Cloud gate|to Theron's balcony|back to the Dream Gate|na} is a blur.

*label declaration2

@{(chose) Zeus's gilded palace is empty, eerily so. You suppose most of its divine inhabitants have better things to do than promenade its resplendent halls|And, once again, the Lord of Leukas is awake, absent-mindedly whittling while gazing up at the stars|Soon, you're nearing the Erebus mountains, still bearing the scars of Argus's escape|na}.

*if chose = 1
    Only when you traverse them yourself does it dawn on you that you have no clue where Ares's chambers are. 

    Then again, you doubt that's where you'll find him.

    [i]I feel more at home in the kitchen than I do anywhere else in my father's palace,[/i] he'd written once. [i]It has everything I need; a sturdy table to write you scrolls, a nice view of the herb garden, and unrestricted access to snacks. Were I more prone to sleeping, I would build a pallet close to the hearth and do it here.[/i]

    Right enough, when you journey to the fringes of the palace–a route you know well, even if it has been a few mortal lifespans since you last trod it–and reach the kitchen, he's there. Sitting at a table that looks sturdy indeed, hunched over a scroll drenched in the golden light pouring in through the portico.

    "Back so soon, Maia?" he asks, not bothering to look up. "I thought they wouldn't let you leave that beach until after the fea…Oh."

    He lets go of the quill and bolts to his feet when he realizes it's you, not the nymph, at the kitchen door. His head collides with the herbs hanging from the wall before he stammers, "${name}. What are you doing here?"
    *goto declaration3
*elseif chose = 2
    His hands slow when he spots you. Stars glitter in the depths of his dark eyes as he watches you land @{(flightstyle) with a gentle swoop of your wings|and gently shrug off your shadows|with a gentle swoop of your wings}.
    
    You glance at the half-finished cup between his fingers, then at the wooden @{(epiali) snake|bat|raven|cat|spider} perching on the table beside him. He was working on it the first time you encountered each other like this–on this balcony, in the middle of the night, when he should've been asleep. He's finished it now, @{(epiali) each scale|jointed wings|each feather|curling tail|each furry leg} perfectly rendered.

    But it doesn't hold your attention for long. How could it, when Theron's gaze is like a rip current, recklessly pulling you towards him?
    
    And yet, when you let yourself be drawn to it, his expression gives away nothing of what he might be feeling.

    "Goddess," he greets you in that deferential but firm way of his.
    *goto declaration3
*else
    *set alreadynaked true
    Much like @{(injured) yourself|Morpheus}, you suppose.
    *goto underworlddescription

*label underworlddescription

Thanks to your mother's efforts, the wood is no longer a smoke-filled @{(chose) wasteland|wasteland|wasteland, at least|wasteland}. Already she has risen many a sapling to replace the trees that perished in Argus's wake, and pockets of green have begun to emerge among the grey, not-so scorched earth. Earth that hasn't quite healed yet, but is on its way.

*if chose = 3
    You're about to head to Morpheus's home, or rather, his cave, when a silver glint catches your eye.
    *goto morpheuslake
*else
    *goto main73

*label morpheuslake
*page_break There
 
@{(leaningtowards < 3) Morpheus, waist-deep in a mist-cloaked lake at the foot of the moutnains|Waist-deep in the same misty lake he was in when he wondered what it feels like, when souls forget. Morpheus}.

You land @{(leaningtowards < 3) on a large rock jutting out of the water, ruffling its glinting surface. He has his back to you, wings wrapped around his shoulders like a shroud. If it weren't for the glow of his long, white hair and the sheen of his pearly skin, it would be impossible to tell where his wings end and the water begins|on the same rock you did then, sending ripples skittering across the water's smooth surface}.

@{(leaningtowards < 3) He turns around, revealing the well-defined panes of his torso, the honed arrow point of his hips. What's beneath them, however, remains hidden by the water|This time, he turns around immediately}. 
    
@{(leaningtowards < 3) "My eyes are up here, Princess."|"The ogling is getting out of hand, Princess."}

*if goinginlake = true
    Once again, you shut him up by ripping off your gown and lowering into the water. Once again, it works. 
        
    His gaze burrows into your naked @{(injured) body, snagging on your scar but only for a moment|body}. @{(demure < 50) You lift your chin|You ignore the blush creeping into your cheeks}. Whatever happens this night, whatever wants and desires are spoken, you ought to speak them without a lake between you.
    *goto declaration3
*else
    @{(leaningtowards < 3) You|This time, you don't hesitate to} rip off your gown and lower into the water. Whatever happens this night, whatever wants and desires are spoken, you ought to speak them without anything standing between you.
    *gosub_scene subroutines lake
    *goto declaration3

*label declaration3

What do you do?

*fake_choice
    #I lay it all on the line and tell him how I feel about him.
        *set leadership %+5
        *set confession 1
        @{(leadership > 60) You meet his gaze, bold and brave and ready to face whatever he has to say in return|Taking charge doesn't always come easy to you, and doing so about this, with him, is no different. But you force yourself to meet his gaze and speak your feelings all the same}.

        @{(chose) "I know what I want,"|"I don't want to pretend,"|"I don't loathe you either,"|na} you tell him. @{(chose) "It's you. Not because it's what our parents want, not because it will strengthen our realms' alliance. But because, when|"I want to feast and dance with you. I want to build a pallet by the fire and listen to terrible poems with you. I want to fall asleep under the stars with you. When|"Not really. Even if you deserve it. Even if you're an arrogant fool. Because, for some Fatesforsaken reason, when|na} I think about my future, it's you who I see. I don't have the gift of foresight, I can only guess at what the Fates have in store for us. But I would like there to be an [i]us[/i]. And I would like us to face whatever twisted pattern they have in mind, together."
    #I pluck up all my courage and ask him how he feels about me.
        *set demure %-5
        *set confession 2
        @{(demure > 55) Forcing yourself to meet his gaze, to speak your feelings, is a struggle. But you do it all the same|You hold his gaze, bold and brave and ready to face whatever he has to say in return}.

        @{(chose) "If I wasn't your parents choice. If I wasn't what was best for the realms. Would you still chose me?"|"What would you do, if we didn't have to pretend or wish for things to be different?"|"Back in your chambers, you said you were wrong about loathing me. That it wasn't hatred that made you seek me out. So, what was it?"|na}
    #I test the waters in an attempt to gauge how he feels about me.
        *set cunning %+5
        *set confession 3
        @{(cunning > 55) Subterfuge has served you well in the past. Why not use it here, now, with him?|You've never been one for subterfuge, but you can't bring yourself to confess your feelings until you're certain about his, and you can't bring yourself to ask about them outright}.

        "I've been thinking a lot about my future lately. About what the Fates might have in store for me. About who I might want to face it with," you sigh, @{(cunning > 55) keeping your tone cool and casual|aiming for a cool and casual tone, and completely missing the mark. Your nerves make your voice crack, and your fingers itch to figdet}. "Have you been thinking about that sort of thing too, per chance?"

        @{(chose) His eyes widen, and he glances at the scroll|He raises a dark eyebrow at you|His lips twitch, not quite a smile, but not far off|na}. "As a matter of fact, I have."

        @{(cunning > 55) You meet his gaze|You swallow hard}. "I see. And did your reach any interesting conclusions?"

*page_break

For a long, agonizing moment, he does nothing. Doesn't move, doesn't speak, doesn't so much as blink as @{(chose) rosemary shoots shed green needles onto his shoulder|a rogue wood shaving curls to the floor, landing at the top of the pile between his feet without making a sound|mist curls around his wings and water laps at his waist|na}.

*if chose = 1
    Then he picks up the scroll and reads it aloud.

    "${name}. I wanted to apologize for my embarrassing turn during my recent visit to your realm. The wooziness has finally subsided, but the shame remains, as does my fear of Averna." He pauses, hazel eyes darting ahead as he offers mumbled snippets of what follows. "Hear you've been busy…@{(hermespunished) nasty business with Hermes|does the committee compare to the Council}…Cerberus is worth losing a hand for."

    He trails off, gaze still searching.
    
    "Ah, here it is," he announces, glancing at you before clearing his throat and returning his attention to the parchment. "When I suggested we have fun together and get to know each other again, I suspected it was a bad idea, because already I could feel myself drawn to you like I used to be when we were godlings. Already, I could feel myself wondering whether the Fates might truly be so kind so as to grant me both peace and happiness.

    "Those feelings only grew every time I heard your laugh, or read your scrolls, or @{(aresoutcome) na|na|imagined you reading mine|felt your lips on mine|felt your lips on mine}. And my suspicions were confirmed. It was a bad idea indeed, because I realized I would gladly be strong-armed into anything, and agree to any terms, so long as it meant a future with you."

    He meets your gaze @{(confession < 2) anew.|anew. "Does that answer your question?"}
    *gosub_scene subroutines declaration4
    *goto declaration5
*elseif chose = 2
    Then he sets the cup down on the table, next to the @{(epiali) snake|bat|raven|cat|spider}, wipes his hands on his simple chitoniskos and gets to his feet.

    @{(confession > 1) "Well, first of all, I've concluded that I would like to stop pretending and wishing for things to be different. I want to feast and dance with you. I want to build a pallet by the fire and listen to terrible poems with you. I want to fall asleep under the stars with you." He fastens his gaze on yours. "My|"My} time in this world may be short, but however much of it the Fates grant me, and for as long as a goddess such as yourself can bear it, I offer it to you, alongside my heart."

    "Even if we are doomed?" you whisper around the lump in your throat. Because @{(confession) you might've laid it all on the line, but you still have|You have|You have} to hear him say it. You have to know that he knows. That he understands.

    There's no sorrow in his face, no bitterness in his voice when he answers. 
    
    "I'm doomed either way. But it's never easier to forget, than when I'm with you. Here. In my dreams." He pauses, smiling. "In my @{(confession < 2) nightmares.|nightmares. Does that answer your question?"}
    *gosub_scene subroutines declaration4
    *goto declaration5
*else
    "I realized love was killing my mother long before she died, so I promised myself I would never be foolish enough to feel it," he finally says. "But, from the first time I saw you at your father's palace, @{(hobby) weaving in the courtyard|practicing the javelin in the courtyard|playing the aulos in the courtyard|playing kncuklebones in the courtyard}, you threatened that promise."
    
    You remember. You had looked  @{(hobby) up from your tapestry|away from your target|up from the instrument|up from the game} and found him leaning against a column, staring at you.

    You had @{(charm > 60) invited him to join you, of course|stared right back, of course}. He had an almost feral look about him. His mop of silver hair was sticking up in places, his wings were too big for his lanky frame, and he was covered in soot. Later, you learned he had snuck into the cyclops' workshop and attempted to steal one of Zeus's lightning bolts.

    Then his father had appeared, dragging him away, leaving you to wonder @{(charm > 60) if he might've taken you up on the offer|what his problem was}.
    
    "@{(charm > 60) The kindness you showed me|The way you looked at me}…it made me curious about you in a way I hadn't been curious about anyone," he adds, fastening his gaze on you. "And when that curiosity grew, when I felt myself drawn to you over and over, thinking about you all the time, I fought against it, desperate to cling to my promise. Refusing to accept it was in vain. Because no matter how hard I tried to deny it or how cleverly I attempted to disguise it, I broke that promise a long time ago." 
    
    He smiles, small and soft, and a little sorrowful. "My heart may be jagged, wretched and rotten. But it's yours. It always has @{(confession < 2) been.|been. Does that answer your question?"}
    *gosub_scene subroutines declaration4
    *goto declaration5
 
*label declaration5

*if laterkiss = false
    Though it's more promise than kiss. An oath that needs no Stygian water. Only @{(chose) his arms gently wrapped around your waist and the taste of ambrosia lingering on his lips|his arms wrapped around your waist, steady despite the wild beat of his heart against your chest, and the taste of salt on his tongue|his arms around your waist and the rough silk of his hair beneath your fingers|na}.

    You forget where you are. [i]Who[/i] you are. Will you ever get used to this? Will it ever not make your head spin, your senses jolt awake?
    *goto declaration6
*else
    *goto declaration6

*label declaration6
*page_break

Breaking the kiss doesn't make you any less affected by it.

*if marriage = 4
    "You should know that I don't wish to marry. Ever. For any reason," you say, not quite breathless but close to it.

    Still, if you're going to do this, he should know where you stand.

    He nods. "And you should know that I don't believe love needs to be validated with some boring ceremony to be real."

    Your relief is instant. Good, that's good.
    *goto declaration7
*else
    *goto declaration7

*label declaration7

*if others
    @{(marriage < 4) "You should|"You should also} know that, while you are my future, you haven't been the only one in my recent past," you @{(marriage < 4) say, not quite breathless but close to it|say}.

    @{(confession) You're laying it all on the line, after all|He was honest with you. The least you could do is be honest in return|}.

    He @{(chose) nods|nods|smirks|na}. "And yet, you are here with me, not wherever they may be, with them."

    He doesn't sound bothered. In fact, there's an undercurrent of mischief in his voice, a roguishness to the way he looks at you.

    @{(marriage < 4) That's good, too|Your relief is instant. Good, that's good}. 
    *goto declaration8
*else
    *goto declaration8

*label declaration8

"What now?" he wonders, holding you close.

*choice
    #I just want us to hang out.
        *set finaloutcome 1
        I glance around. "How about @{(chose) some ambrosia cake?"|we tuck up under the stars?"|a swim?"|na}
        
        He smiles, letting his hands slide away from your face. "I like the sound of that."
        
        *if chose = 1
            And, as he wraps an apron around his broad frame and patiently walks you through Maia's coveted recipe, it dawns on you.
            *goto premain72
        *elseif chose = 2
            He disappears briefly, returning with a blanket and a pitcher of wine. 
            
            He can't see the constellations as clearly and as brightly as you can so, with your head nestled in the crook of his arm, you describe them to him as vividly as you can, peppering anecdotes of the gods and mortals who inspired them.
            
            And, as he dozes off, his soft breaths tickling your hairline, his heartbeat slowing beneath your palm, it dawns on you.
            *goto premain72
        *else
            And, as you dive deeper into the lake, chucking water and challenges at one another, unable to stop grinning, it dawns on you.
            *goto premain72
    #I just want us to kiss.
        *set finaloutcome 2
        You lace your fingers behind his neck. "How about you kiss me some more?"

        He pulls you closer and smiles. @{(chose) "With pleasure."|"As you wish, Goddess."|"Your wish is my command, Princess."|na}

        And, when his mouth finds yours anew, it dawns on you. 
        *goto premain72
    #I want us to enjoy each other's bodies in full.
        *set finaloutcome 3
        "I have some ideas," you tease.

        @{(chose > 2) The water is shallower here than where he stood, reaching only your hips. And, though it's cold, you don't think it's responsible for|Despite the layers of fabric between you, you feel} the shiver that goes through him when you press your body to his.

        His hands slide away from your face to gently trace the curve of your spine. "You do?"

        @{(chose > 1) He asks it casually, but there's nothing casual about the way he's looking at you. All hunger and longing and anticipation|He sounds almost surprised, as though he can't quite believe his luck. But beneath his blushing cheeks and bashful gaze, you can sense the same heady mixture of hunger, longing and anticipation pulsing through you}.

        @{(chose > 1) The same hunger and longing and anticipation pulsing through you|Then you're reaching for one another anew}.

        *if (chose = 1) and (aresoutcome != 4)
            *set firsttime true
            *goto foreplaying
        *elseif (chose = 2) and (theronoutcome < 5)
            *set firsttime true
            *goto foreplaying
        *elseif (chose = 3) and (morpheusoutcome < 5)
            *set firsttime true 
            *goto foreplaying
        *else
            *goto foreplaying

*label foreplaying
*page_break

@{(laterkiss) This time, when your lips meet, it's more promise than kiss. An oath that needs no Stygian water. Only his arms wrapped around you, binding your body to his|Kissing him before had jolted your senses awake. This time, it sets them ablaze}.

You don't remember moving–right now, you doubt you could remember your own name–but you must have, for @{(chose) a trestle tables is suddenly pressing into your lower back, and the neat array of utensils that had been resting atop it clatter to the floor|the rickety wooden table is suddenly pressing into your lower back and his whittling knife clatters to the floor|your lower back is suddenly touching the rock, and your discarded clothing is wet|na}.

It doesn't deter either of you. His lips stray from your mouth, but they're just as deft at consuming your thoughts when they brush your jaw on their way to the soft spot behind your ear.

"What sort of ideas?" he murmurs.

The words take a few moments to register. His hands have found purchase on your hips, and you can feel how hard he is between them. When comprehension finally takes hold, you answer by

*fake_choice
    #@{(chose > 2) Tilting my head back|Removing my gown} to give him better access.
        *set alreadynaked true
        *set foreplay 1
        "I was thinkig something along these lines," you breathe, @{(chose > 2) bearing your throat to him, half offering, half plea|tugging at the pins holding your gown together}.      
        
        @{(chose > 2) You glimpse two souls floating in the mist canopying the lake and smile before his lips embed in your neck, and his lean body molds to yours anew|He's all too eager to help, swiftly yanking them out and gently pulling the gown over your head before tossing it onto the floor}.

        @{(chose > 2) Then you're gasping and sliding your hands beneath his wings|He takes in your exposed body, heat flaring in his gaze. Then his lips embed in your neck, and you're tilting your head back}, all that hunger and longing and anticipation pooling between your thighs. You spread them wider, desperate for his touch.
        
        He doesn't provide it. Not there, anyway. Not yet. 

        Instead, he cups one of your breasts and brings his mouth to the other.
        
        "Good idea," he says before dragging his tongue across your skin.
        
        @{(chose) You catch glimpses of your reflections in the pots hanging from the ceiling. You, naked and desperate to feel him closer. Him, dressed and too busy teasing you to oblige|The stars wink down at you as he teases you|Mist closes in as he teases you|na}. His taunting soon becomes too much to bear without letting your eyes flutter closed and your back curl over the @{(chose > 2) rock|table}. 
        
        The scrape of his teeth only makes matters worse.
    #Reaching @{(chose > 2) down to cup him|beneath his chiton}.
        *set foreplay 2
        "I was thinking something along these lines," you say, wrapping your hand around his cock.

        He stills, lips frozen above your clavicle, fingers clamping down on your hips. 

        "What do you think?" you wonder, @{(demure > 55) trying not to blush|all feigned innocence}.
        
        When he leans back, heat flares in his eyes, @{(chose) glowing under the light pouring in through the portico|glinting under the stars|glinting under the dim, mist-coated sky|na}. 
        
        "Good idea," he rasps, anchoring them on you.

        You begin pumping him then. Slow, drawn-out strokes that appear to delight and torment him in equal measure. When you pick up the pace, his eyes flutter closed and he tilts his chin back, exposing his @{(chose) tanned|scarred|pale|na} throat.

        Kissing it draws a strangled little gasp from his lips.

        @{(chose) "Fates|"Gods|"Fates|na}," he pleads.

        But you continue working his cock steadily.
    #Guiding his hand @{(chose > 2) between my thighs|beneath my gown}.
        *set foreplay 3
        It's only fair he knows you want him just as bad.

        "I was thinking something along these lines," you breathe, spreading your legs for him. He leans back, heat flaring in his eyes, @{(chose) glowing under the light pouring in through the portico|glinting under the stars|glinting under the dim, mist-coated sky|na}.
        
        @{(chose) His knuckles gently graze|His calloused palm scrapes|His rings scrape|na} the inside of your thigh. "Good idea." 
        
        His voice is low, and it hitches when you bring his fingers to your center. All that hunger and longing and anticipation has pooled there, making you wet and eager. You steer his hand with yours, intent on holding his gaze and some composure–you're only getting started, after all.
        
        Alas, you promptly fail at both. The friction is too much to bear without letting your eyes flutter closed and your hand fall away. He sets his own pace with a @{(chose > 2) satisfied|soft} smirk, but it only makes matters worse.
*if foreplay != 2
    Or, you suppose, better.

    So much better.
    *goto foreplaying1
*else
    "@{(chose) What of them|What|What of them|na}?" you ask @{(demure > 55) sweetly|triumphantly}.
    *goto foreplaying1

*label foreplaying1
*page_break

@{(foreplay) The sound of his voice, low and full of promise, draws your gaze to his, where heat has flared|He regains enough composure to look down at you and utter,|He keeps working you with slow, steady strokes, so much so that you almost don't hear him suggest,} "Perhaps I should demonstrate some of [i]my[/i] ideas now."

@{(foreplay > 2) It could be argued he's been doing just that. With great skill, in fact. What|What} do you do?
    
*choice
    #I agree to it, more than happy to hand over the reins.
        *set wholeads 1
        @{(foreplay) You untangle your fingers from his hair|You give him one last stroke before letting your hand fall away|Forming a sentence with his hand between your thighs requires every last shred of your willpower}. "By all means."

        The heat in his gaze grows wilder. @{(foreplay) Then he straightens, eyeing|Then he eyes|He removes his hand and you almost cry out in protest. Then he eyes} your @{(alreadynaked) naked body with a wicked grin. Is he thinking about all the things he might to do to it? You certainly are|dishevelled gown with a wicked grin. "Let's start by removing this, shall we?"}

        @{(alreadynaked) He comes closer. Almost by reflex, you open your mouth and spread your legs wider, ready–no, desperate–for whatever ideas he plans on demonstrating. But all he does is ghost his lips over yours. Once, twice, three times. With every second he doesn't touch you,|He makes a meal out of it. Carefully sliding each strap down your shoulders, gently hiking your skirt up your thighs and over your hips. And, every time his fingers graze your skin}, the rope of desire binding you to one another tightens.

        @{(alreadynaked) Unable to take it any longer, you reach for him instead. He|By the time he's done undressing you and drinking in your naked body, you're aching with impatience. But, when you reach for him, he} catches your wrists and laughs, "Impatient much?"

        @{(chose) His cheeks may be flushed, his smile sheepish, but he sounds more sure of himself than ever before.|He looks so pleased with himself, so confident|His expression teeters between smugness and excitement, just like it always does when he beats you back to the gate|na}. It comes closer to undoing you than all the taunting had.

        "Can you blame me?" you gasp out.

        He shakes his head before leaning in as though to kiss you. Right before your lips meet, he sinks to his knees instead. The height of the @{(chose) trestle table|table|rock|na} brings his mouth perfectly in line with your hips.
        
        "I had better get to feasting, then," he says.
        *goto oral
    #I allow it, curious about what he might do if you give in.
        *set wholeads 2
        @{(foreplay) You bring your hand to his neck, nails grazing his hair|You give him one last stroke before dragging your fingers up his chest|Forming a sentence with his hand between your thighs requires every last shred of your willpower}. "Think you can do better?"

        @{(chose) A sheepish smile peels across his face|You didn't intend it at as a challenge but, judging by the way his lips quirk up and the excitement darting across his dark eyes, he seems to take it as one|You didn't intend it as a challenge, but of course Morpheus would take it that way. His expression shifts, teetering between smugness and excitement, just like it always does when he's racing you back to the gate|na}.

        "I guess there's only one way to find out," he @{(chose) answers. His cheeks may be flushed, but he's never sounded this sure of himself before. The|answers, sure of himself and not afraid to show it. The|answers, all unbridled arrogance. And yet, it doesn't keep the|ba} rope of desire binding you to one another @{(chose > 2) from tightening in response. If anything, it encourages it|tightens in response}.

        @{(alreadynaked) Still, you regard him carefully|When he reaches for your gown, you help him remove it. Once it's gone and you've sufficiently enjoyed the way he drinks in your naked body do you speak anew}.@{(chose < 3) "I guess so. What do you have in mind?"|Just because you want him–and you do want him, desperately so–doesn't mean you're about to let his entitlement go unchecked. "Are you actually going to demonstrate anything or are you just going to keep talking about it?"|na}
        
        He wastes no time sinking to his knees. The height of the @{(chose) trestle table|table|rock|na} places his mouth perfectly in line with your hips. 
        
        "Oh, @{(chose < 3) I'm planning on a|I'm going to|na} feast," he assures you.
        *goto oral
    #I deny him. @{(foreplay) I want to be the one in charge|I'm enjoying being the one in charge too much|I'm enjoying being the one in charge too much}.
        *set wholeads 3
        "I don't think so," you say.
            
        @{(foreplay) Then you catch his chin between your fingers, dragging his face back to yours|Then you give him one last stroke before dragging your fingers up his chest|Putting a stop to his strokes requires every last shred of your willpower, but you do, removing his hand and lacing your fingers together}.
            
        "Shall I show you what you can do instead?" you continue, @{(foreplay) ghosting your lips over his|catching his chin between your fingers|surprised at how in control you sound, considering how much you're trembling}.

        @{(chose) He nods heartily|His throat bobs|He grins, wide and wicked|na}. "Anything."
        
        How could a single word come so close to undoing you? 
        
        Heart close to pounding, you consider your options. Will you push the rope of desire binding you to one another to its limit? Or will you quit playing and give it free rein?

        *choice
            #Push it. I hop onto the @{(chose > 2) rock|table} and gesture for him to get on his knees.
                He obliges. The Fates must've known it would come to this, for the height of the @{(chose) trestle table|table|rock|na} brings his mouth perfectly in line with your hips.

                He knows beter than to do anything about it yet–you're the one in charge, after all. But, judging by the way he's gripping the @{(chose > 2) rock|wood} at either side of you, you can tell he wants to.
                
                Smiling, you @{(alreadynaked) run your hands over your body, relishing the way it seems to both pain and please him to watch you do it. Only when|make a meal of removing your gown, taking your time with each pin before gradually hiking the fabric up your body and over your head. Only when you're naked and} you yourself can't bear the absence of his touch do you deliver your command. 
                
                "Feast."
                *goto oral
            #Quit playing. I hop onto the @{(chose > 2) rock|table} and hook my legs around his waist.
                *set skippedforeplay true
                *goto presex
            #Quit playing. I push him onto the @{(chose > 2) rock and down on his back before straddling|chair by the table and straddle} his hips.
                *set ridehim true
                *set skippedforeplay true
                *goto presex

*label oral
*page_break

And feast he does, face buried between your thighs, @{(wholeads < 3) hands clasping your hips to angle them|knuckles grazing your hips}.

*if wholeads != 3
    His tongue is as merciless as it is precise, doling out its own kind of twisted worship with each stroke. Once he works out exactly where to focus them, and how fast to deliver them so that you're moaning and rolling your hips and gripping the @{(chose < 3) wood|rock} at either side of you, he does it over and over.

    Every time pleasure threatens to overcome you, he slows right down, or stops altogether, before repeating the process.

    It's torture. Maddening, delicious torture.

    *choice
        #I'm a glutton for punishment; I submit to it gladly.
            Your @{(flightstyle) wings|shoulders|shoulders} press into @{(chose) wood and tiles|vines and wall|rock|na} as you lay back and give yourself over to him.

            He deals another wave of torment, pushing you all the way to the edge, where he leaves you teetering to ask, "Enjoying the demonstration?"

            "Yes." You answer so fast, it draws a laugh from him.

            "Good, because I'm not done yet."

            You glance down at him, still ensconced between your thighs, still @{(chose) so sure of himself|so sure of himself|smug|na}, and all you can manage is a weak, "Oh?"

            "I've been greedy, toying with you like this," he says, nipping the inside of your thigh. "I think it's time I made it up to you."

            You nod, trembling against him.
            *goto oral1
        #I pretend it isn't; he ought to suffer some too.
            "Nice…idea," you manage.

            His gaze snaps up, @{(chose) keen|dark|bright|na} and suspicious. "Nice, huh?"

            "Yes."

            More than an answer, it's a challenge. He nips the inside of your thigh and you have to bite back a moan. Your body betrays you anyway, trembling against him, letting him know the extent of the effect he has on you.

            He grins, and determination settles over him. "I had better up my game, then. Nice won't do. It won't do at all."
            *goto oral1
        #I can't take it any longer; I want him inside me.
            *set interruptedforeplay true
            You tug at his hair.
            
            He looks up at you, mouth still on your skin, hands still on your hips. "Yes?"

            He sounds slightly miffed, as though you just interrupted something very important. Which you suppose you did.

            "This was a great idea," you manage, voice trembling in tune with your body, "but I have a better one."

            "I doubt that." When he nips the inside of your thigh, you have to bite back another moan.

            "I guess there's only one way to find out," you say.

            He grins and lets you drag him to his feet.
            *goto presex
*else
    You tug at his hair and arch your hips, showing him exactly where you want his tongue to go, and how fast he should deliver each stroke.

    He obeys, diligent and precise. Tasting you, yes, but also worshiping you with every well-placed lick, earning every moan that escapes your throat.

    Just as pleasure is about to overcome you, you gasp out another command:

    *choice
        #"Look at me."
            His gaze snaps up, @{(chose) warm|dark|bright|na} and eager.
            *goto postorder
        #"Touch yourself."
            He grunts against you, then he removes one of his hands from the @{(chose < 3) table|rock}.
            *goto postorder
        #"Don't stop."
            He hums against you in agreement, driving himself further between your thighs.
            *goto postorder
        #"Come here. I want you inside me."
            *set interruptedforeplay true
            He shoots to his feet so fast you almost lose your balance.

            "Eager, much?" you tease.

            "Yes," he grunts.

            But you can't blame him.
            *goto presex

*label postorder

His willingness to please you, to do as you ask without hesitation, to put himself at your mercy, is as heady as the brush of his tongue.

And the very thing that pushes you over the edge.

*goto oral2

*label oral1

@{(wholeads > 1) He makes good on that promise|He rises to the challenge} alright, driving himself further between your thighs, quickening the swipes of his tongue, sliding a finger inside you to aid them.

*label oral2

@{(wholeads < 3) And this time, he doesn't stop|He doesn't stop its strokes}. Not when you throw your head back, not when you writhe against him, and not when you cry out as release @{(wholeads < 3) finally finds|finds} you, @{(wholeads < 3) carrying all that glorious, agonizing build-up with it|hard and fast and obliterating}.

*page_break

You haven't fully recovered from it when @{(wholeads < 3) he gets to his feet and cups your face|you cup his face and help him to his feet}.

@{(wholeads) "Greedy indeed," you sigh|"Now that I know the effect the word nice has on you," you warn. "I shall be using it more often."|"So willing to please," you say, voice trembling as much as the rest of you. "You ought to be rewarded for it."}

A smile tugs at the corner of his mouth. @{(wholeads) "Can you blame me?"|"You will?|"What do you have in mind?"}

@{(wholeads < 3) He presses his lips to yours|You press your lips to his}, soft and sweet. But your taste lingers on his tongue, and when it touches yours, it reignites the embers of your desire, still aglow between your thighs. 

You hook your legs around his waist. @{(wholeads) "Only if you don't stop now," you answer|"Nice. Nice. Nice," you say, punctuating each instance of the word with a kiss|"Some release of your own," you answer}.

@{(wholeads) "No need to worry about that," he rasps.|"In that case," he rasps.|"I wouldn't mind that," he rasps. "I wouldn't mind that at all."}

*goto presex1

*label presex

Another time, you'll take things slow. @{(wholeads < 3) Let him torment|Torment} and tease and taunt @{(wholeads < 3) you|him} until you're both as spent as @{(chose) a pair of deities|a goddess and a mortal|as a pair deities|na} can be.

Not this time. This time, @{(skippedforeplay) you need him inside you, and you need him now|your need for him is too great, too unwieldy to do anything but hook your legs around his waist and pull him closer}.

*label presex1
*page_break

*if chose = 3
    His wings are splayed @{(ridehim) across the rock, tips|at either side of him, underside} dipping into the water. 

    You run a hand up and down the iridescent panes, gently tracing the shape of his scar. He watches you do it with a tenderness you never knew he was capable of.

    @{(injured) Then he touches your own scar, as tender with his fingers as he is with his gaze. It's|It's} as intoxicating as everything that has lead to this moment.
    *goto presex2
*else
    @{(wholeads < 3) You tug at his chiton. He helps you yank|Take it off," you order, nodding at his chiton. He quickly yanks} it over his head, as desperate for this as you are.

    @{(firsttime) You take the opportunity to admire|You've seen it before, have thought of it much since, but that doesn't stop you from admiring} his naked body.

    @{(chose < 2) His leather cuirass and red tunic blunt its sheer brawn. Without them, he looks more like the war god he was born to be. Powerful, brutal and fierce|The outline of his toned arms, the planes and grooves of his torso, the dark hair knotted across his chest. Sweat glistens on his warm skin, lightly flecked with nicks and scars}.

    @{(chose < 2) And yet, his hazel eyes are warm, his big hands gentle on your skin as he patiently waits for your next move|Signs of his mortality. Reminders to make the most of whatever time the Fates grant you by his side}.
    *goto presex2

*label presex2

@{(chose < 3) So you|The moment when you} @{(ridehim) brace your hands on his chest|brace your hands on his rear} and @{(ridehim) lower onto him|guide him inside you}. 

*if virgin
    *set virgin false
    There's a suggestion of pain, a fleeting sting that parts through the lust clouding your mind to point out you haven't done this before. Not this part, anyway.
    *goto checkin
*else
    You can't help but….
    *goto sex

*label checkin
*page_break

Sensing the shift within you, @{(chose) Ares|Theron|Morpheus|na} freezes.

"Are you alright?" he asks, searching your face for the cause of your hesitation. His is pinched with concern. "We don't have to do this."

He makes to @{(ridehim) lift you off of him|pull away} but you clench around him and it stops him in his tracks anew.

"That won't be necessary," you assure him.

After all, you're a goddess. The pain is already a distant memory, gone as quickly as it arrived. 

But that doesn't mean you aren't aching. For him, for this.

Seeking to relieve that ache, @{(ridehim) you sink into him|guide him deeper} and let out a….

*label sex

*fake_choice
    #Swear.
        "Fates."
    #Sigh.
    #Whimper.
    #Moan.

Being filled by him like this feels too good not to.

@{(chose) "Fates,"|"Gods,"|"Fates,"|na} he gasps in return, @{(ridehim) tilting his chin back|pressing his forehead to yours}.

For a moment, all you're able to do is stare at one another. Unmoving, yet already sizing up the finish line. Because even though you're both perfectly still–breaths held, eyes locked–it's hard not to believe your bodies were made to fit one another.

And, when @{(ridehim) you begin grinding against him|he begins thrusting into you}, you know it to be true.

Your awareness narrows, latching onto @{(chose) the heat of his hands on your hips, the softness of his curls beneath your fingers, the taste of his skin between your lips|the scratch of his beard beneath your fingers, the imprint of his calloused palms on your skin, the taste of his sweat between your lips|cold bite of his rings against your hips, the silkiness of his hair beneath your fingers, the taste of his skin between your lips|na}.

*page_break

*if ridehim = true
    @{(chose < 3) Your feet push against the floor|Your knees dig into the rock} as you quicken your thrusts.

    And though you're the one in control–setting the pace, rolling your hips–you feel as though you're completely out out of it at the same time.
    *goto sex1
*else
    Your legs tighten around his waist and you arch your hips, urging him to pick up the pace.
    
    @{(chose < 3) The table slams into the wall behind you in tune with his increasingly frantic thrusts. And though it's shaking violently and precariously beneath you, you can't bring yourself to care|The rock digs into your skin as he answers your silent plea, thrusting into you faster and harder}.
    *goto sex1

*label sex1

*choice
    #I rake my nails down his @{(ridehim) chest|back}.
        @{(chose) His skin is warm beneath them. You dig into it, letting|Careful not to draw blood, but hard enough to let|His skin is cold and damp beneath them. You dig into it, letting|na} him know how bad you want him.
        *goto sex2
    *if wholeads = 3
        #I bring my fingers to his throat.
            You don't press down on it hard; just enough to feel the moan that tears from his throat against your palm.
            *goto sex2
    *if (ridehim = true) and (chose = 3)
        #I bring his hands to my breasts.
            A strangled sound tears from him as he cups your breasts and watches you drag yourself up and down the length of him with wide, eager eyes.
            *goto sex2
    *if (ridehim = true)
        #I bring his hands to my rear.
            A strangled sound tears from him as he fills his hands with your curves, helping guide your body up and down his length.
            *goto sex2
    *if wholeads != 3
        #He tugs at my hair, pulling it slightly.
            You tilt your chin back and he buries his mouth in your neck anew, wrapping your hair around his fist, tugging it a little harder.
            *goto sex2
    #He reaches @{(ridehim) up|down} to touch me.
        *set hedoesit true
        *goto touch
    #I reach down and touch myself.
        *goto touch

*label touch

@{(hedoesit) He drags the heel of his palm up and down|You rub} the spot above where he is plunging in and out of you, stoking the flames of your pleasure.

*label sex2

"Yes, that's it," he grunts as your moans grow wilder, your body more tense. "Don't hold back. Give me everything you have."

*if interruptedforeplay
    Release crashes down on you, carrying all that glorious, agonizing build-up with it, a tidal wave that obliterates everything else.
    *goto sex3
*elseif skippedforeplay
    Release crashes down on you, a tidal wave that obliterates everything else.
    *goto sex3
*else
    Release finds you anew, a tidal wave that washes away everything else.
    *goto sex3

*label sex3

Pleasure is still rippling through you when he finds his own, as though he had been keeping it at bay, waiting for you to come undone around him before letting loose himself.

You hold onto him through it, kissing his brow, behind his ear, his neck.

After, @{(ridehim) you melt into his chest and he wraps his arms around you|he melts into you, and you wrap your arms around him}.

And as @{(chose) he gently plays with your hair|his ragged breath tickles your hairline and his heartbeat pounds against your chest|his wings gently brush your neck|na} it dawns on you.
    
*label premain72

Nothing could've kept you from this, from [i]him[/i].

Not your @{(chose) families'|family's|family's|na} meddling, not the Giants.

*page_break Not Even The Fates

By the time you part ways, 
*if finaloutcome = 1
    @{(chose) your dress has become a constellation of flour streaks, but a basket of freshly-baked ambrosia balances on your arm, making the journey smell amazing|Theron is fast asleep. He'd pressed the carving of your Epiali into your hand with one of his disarming, crooked smiles|the chill of the lake has almost seeped into your bones|na}.
    *goto main72
*elseif finaloutcome = 2
    you're certain your lips are swollen, even though they technically shouldn't be. 

    @{(chose) They taste sweeter than they should, though that could just be the basket of freshly-baked ambrosia cake Ares insisted you bring back with you playing tricks on your senses|You carry the carving of your Epiali with you. He had pressed it into your hand just before you left. Not as a ploy to kiss you again, he'd assured you, but you'd done it anyway. No point in denying yourself any longer|Your gown had slid into the lake, and it clings to you now, wet and cold and badly pinned. Every time Morpheus offered to help you back into it, he got too distracted kissing you to finish the job|na}.
    *goto main72
*else
    his scent has embedded in your skin, become your own. 
    
    @{(chose) It's sweeter than usual, though that could just be the basket of freshly-baked ambrosia cake Ares insisted you bring back with you|You carry the carving of your Epiali with you. Theron had pressed it into your hand just before you left. Not as a ploy to kiss you again, he'd assured you, but you'd done it anyway. No point denying yourself any longer|Your gown had slid into the lake, and it clings to you now, wet and cold and badly pinned. Every time Morpheus offered to help you back into it, it ended back on the rock alongside his own|na}
    *goto main72

*label main72
*page_break

*if chose != 3
    You can't stop grinning the entire way to the Dream Gate, dawn lighting your way.
    *goto underworlddescription
*else
    *goto main73

*label main73

@{(chose) Once you're through the Dream Gate, you|Once you're through the Dream Gate, you|You|Once you're through the Dream Gate, you} opt to walk home, glad @{(chose) for the sliver of reprieve from your duties, and the chance to daydream about Ares. Even though you just saw him, you can't help but crave his company|for the sliver of reprieve from your duties, and the chance to daydream about Theron. Even though you just saw him, you can't help but crave his company|for the chance to dry off, and grin at every beast you pass along the way|for the sliver of reprieve from your duties}.

You must've been smiling in a way you don't usually–and rather distracted–for you don't notice the figure in the courtyard until he calls out to you. "I did not realize party planning could bring you such joy, daughter."

@{(charm > 60) You mask the fright he gave you behind a smile|You aim your glare at him instead of your weapon, which you wave away before it finishes manifesting into your grasp}.

Your father is sitting on a bench, @{(hobby) by the loom where your tapestry is stretched out, almost finished|absentmindedly kicking tossing stones between his feet|absent-mindedly toying with an aulos|absent-mindedly toying with a handful of knucklebones}.

"Unless, of course," your father adds, "it's something else lifting your spirits so. Or someone."

He gives @{(chose) the cake tucked under your arm|the carving tucked into your palm|your damp gown|you} a pointed look.

*fake_choice
    #"You're @{(chose < 4) right. There is someone|wrong. There's no one,}" I gladly admit.
        *set parents %+5
        *set leadership %+5
    #"And if @{(chose < 4) there is someone|there is no one?}" I ask defiantly. 
        *set parents %-5
        *set charm %-5
    #"Wouldn't you like to know," I say noncomittally.
        *set parents %-5
        *set cunning %+5
        
The scar slashing through his eyebrow twists when he rises it. Then he @{(parentsrel > 1) lets out a deep, long sigh|shoots you a small smile} and waves you closer.

"Come, daughter, let us talk plainly."

You cross the courtyard @{(parentsrel) and take a seat by his side|but refuse to sit, leaning against a column instead|and take a seat opposite him}.

He doesn't [i]look[/i] tired, but there's a tightness to his shoulders, a sullenness behind his gaze that @{(parentsrel) makes you want to bring him a cup of nectar and forbid him from working for a century or two|blunts the glare you hurl at him|makes you soften towards him}.

"@{(chose) So, you and Ares|So, tell me about the mortal|So, you and Morpheus|So, you have decided to remain unmarried}. Don't look at me like that, ${name}. You are my daughter. I @{(chose < 4) know you well enough to know there has been a change within your heart.|always knew your heart would never belong to Ares.}"

*if chose != 4
    "How did you find out?"

    He shrugs, inky black hair melting into his inky black chiton.
    *goto inlove
*else
    "Then why entertain Zeus in the first place?" you demand, teetering between confusion and rage.

    He shrugs, inky black hair melting into his inky black chiton. "For the sake of diplomatic relations, mostly. We also thought it would be good for you to open your mind a little, if not your heart. It's not a bad thing, daughter, to put yourself out there. Even if what you find isn't what you were looking for. Better to know it for certain. Eternity is a long time to dwell on what ifs."
    *goto main74

*label inlove
*page_break 

*if chose = 1
    "I saw him waiting in your chambers, before he took ill. He did not waver, even when his power waned. When he eventually did waver, however, I hear you were very worried about him indeed."

    "And I'm not usually the type to worry about folks who take ill?" you say, teetering between offense and amusement.

    @{(ruthless > 60) "No, you are not," he says, serious.|"That isn't what I meant," he assures you}. "There's also all the scroll writing. You two have kept Iris busy with your little messages. Plus, Poseidon informed me that all Ares could do while in his underwater kingdom was gush about you."

    You @{(demure > 60) blush|tilt your chin up}. "Shouldn't you be happy, that Ares and I have chosen each other? Isn't that what you wanted?"

    His eyes meet yours, one the color of steel, the other the color of mist. Both equally serious. "So long as it's what [i]you[/i] want, too."
    *goto main74
*elseif chose = 2
    "I heard him and his general argue about it in the burial grounds a while back. Or rather, [i]she[/i] was arguing about it. He seemed very much at peace with his fate."

    You gawk at him, unsure if you're more shocked about the fact he was using his connection to the dead to eavesdrop on Theron or the fact he's admitting to it. 

    Your incredulity doesn't faze him. Neither does your annoyance on Theron's behalf.

    "And what fate might that be?" you huff.

    "To be haunted by you, in sleep and awake, in life and beyond," he offers solemnly. "His words, not mine."

    If you needed to breathe, you're certain you would struggle to do it in the wake of hearing such a thing. 
    
    Then your father's eyes meet yours, one the color of steel, the other the color of mist. Both equally serious. How you feel must be written plainly across your face, for he adds, "Ah. I see now that it's what you wish for too."
    *goto main74
*else
    "He told me."

    Your gaze narrows. "[i]Morpheus[/i] told [i]you[/i] about [i]us[/i]. When?"

    His eyes meet yours, one the color of steel, the other the color of mist. Both equally serious.

    "While interrogating him about Argus. He was describing how
    *if argusencounter = 1
        you acquired your injury. He looked both grief-stricken and wrathful and sick with worry all at once. The only other time I've seen that look on a deity was on your mother, after I got this." He points at his eye. Then he glances at @{(scar) your shoulder|your neck|your leg}, and his face softens.
        *goto extrachat
    *else
        @{(argusencounter < 4) you squared up to the Giant|you} and saved his skin. I recognized the awe in his face, and the sheer panic weaving through it. I was equally awed and panic-stricken about your mother when she came to my rescue, the day I acquired this." He points to his scar.
        *goto extrachat

*label extrachat

"So he didn't actually tell you anything," you sigh. 

Still, his words tug at your chest, almost tempting you into returning to the lake to kiss Morpheus some more.

Your father shrugs anew. "It was all I needed to know."

*label main74
*page_break

"So you're aware of my feelings. What now?" you ask, @{(parentsrel) bumping your shoulder into his|watching him suspiciously|watching him closely}.

*if parents > 55
    He tosses you a rare, full smile.

    "Now, @{(hobby) you tell me all about this rather magnificent tapestry your working on," he says, admiring it anew|we play a game of tossing stones, of course," he says, picking one up|you play me a nice song on the aulos," he says handing the instrument over|we play a game of knucklebones, of course," he says, shaking his hand}. "Tomorrow, we worry about the rest."

    @{(parentsrel) "With pleasure," you agree, smiling right back at him|"If you insist," you agree, feigning indifference|"Of course," you agree, smiling right back at him}.
    *goto endchapter
*else
    *if chose != 1
        "While I respect your choice, it certainly won't make things easy, diplomatically speaking. So I had better return to work, and you had better return to your duties. Mitigate the incoming storm."
        *goto hadesgoodnight
    *else
        "Now, I return to work, and you return to your duties. We have a feast to prepare for, after all."
        *goto hadesgoodnight
    
*label hadesgoodnight

Of course. Duty always come first, with your parents. It's @{(parentsrel) understandable. They are rulers. Their realm's wellbeing comes before their own|infuriating|just the way things are}.

@{(hobby) He gives your tapestry another appreciative once-over|He kicks one of the tossing stones|He puts down the aulos|He puts down the knucklebones} then pushes to his feet.

"Good night, daughter."

*fake_choice
    #"Good night, father."
    #"Don't work too hard."
    #"Have fun."
    #"Nice talking to you." 

@{(parentsrel) You mean it, too. But he merely|The words are dripping in sarcasm. But he merely|The words are a whisper, but you know he hears it. He} waves you off, already melting into the shadows engulfing the courtyard.

*label endchapter

*choice
    #Continue to the next chapter.
        *finish
    *if (not(choice_randomtest)) #Restore to the previous checkpoint.
        *restore_checkpoint